Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

Verschiedene Dateien Verschieben und alte version umbenennen

Frage Entwicklung Batch & Shell

Mitglied: jo4884

jo4884 (Level 1) - Jetzt verbinden

14.04.2010 um 10:59 Uhr, 4613 Aufrufe, 8 Kommentare

Ich bin ein absoluter Neuling im umgang mit Batch und
brauche dringend hilfe.
Hab schon das Forum durchsucht, find aber irgendwie nicht das was ich suche oder ich versteh es nicht.
Bitte um Hilfe!

Ich habe 2 Ordner (Input und Work). In beiden Ordern befinden sich 5 Unterordner die in Input und Work gleich benannt sind.
Im Inputordner befinden sich verschiedene dateien (.pdf, .doc, .docx, ...)
Ich möchte jetzt das alle dateien aus den Unterordnern von Input in die jeweiligen Unterordner von Work verschoben werden.
Weiter soll vorher geprüft werden ob eine Datei aus dem Inputordner schon im Workordner vorhanden ist.
Falls das der Fall sein sollte soll die Datei aus dem Workordner umbenannt werden
(z.B.: test.txt sol werden zu test_alt1.txt)
falls die datei test.txt jetzt zum dritten mal verschoben werden soll, dann soll test_alt1.txt zu test_alt2.txt werden
und test zu test_alt1.txt

Ich hoffe auf eure Hilfe
Mitglied: user217
14.04.2010 um 11:18 Uhr
probier mal das programm allway sync, vielleicht hilfts.
Bitte warten ..
Mitglied: jo4884
14.04.2010 um 11:37 Uhr
Ich hätte es gern als Batchdatei!
Bitte warten ..
Mitglied: LotPings
14.04.2010 um 12:31 Uhr
Hallo jo,

eigentlich mag ich es nicht fertige Lösungen vorzusetzen, aber dies ist ein schönes Beispiel für einen rekursiven Aufruf einer Subroutine.
Der Einfachheit halber habe ich das "alt" weggelassen und gehe davon aus das sich in den Dateinanen ansonsten kein "_" befindet.
01.
::MoveVersion.cmd::::::::::::::::::::::::::::::::::::::::::::::::::::::: 
02.
@echo off & setlocal EnableDelayedExpansion 
03.
Set SrcFld=D:\Test\2010-04\Input 
04.
Set DstFld=D:\Test\2010-04\Work 
05.
Pushd "%SrcFld%" 
06.
For /f "Delims=" %%A in ('Dir /B/S/A-D *') Do Call :Proc "%%~fA" 
07.
Popd 
08.
goto :EOF 
09.
:Proc 
10.
echo ---- %1 
11.
Set "Var=%~dp1" 
12.
Set "DestPath=!Var:%SrcFld%=%DstFld%!" 
13.
If Not Exist "%DestPath%" MD "%DestPath%" 
14.
Set "Dest=%DestPath%%~nx1" 
15.
if Exist "%Dest%" Call :VersionInc "%Dest%" 
16.
echo Move %1 "%DestPath%"  
17.
Move %1 "%DestPath%" >NUL 
18.
Goto :Eof 
19.
:VersionInc %1 
20.
Setlocal 
21.
Set Cnt=0 
22.
For /F "Tokens=1,2 delims=_" %%B in ("%~n1") Do ( 
23.
  Set Name=%%B 
24.
  Set /A Cnt=%%C+1 
25.
26.
Set "NewName=%Name%_%Cnt%%~x1" 
27.
If Exist "%~dp1%NewName%" Call :VersionInc "%~dp1%NewName%" 
28.
Echo Ren %1 "%NewName%" 
29.
Ren %1 "%NewName%" 
30.
Goto :Eof 
31.
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Gruß
Lotpings

Edit zum begrenzen auf 3 archivierte Versionen zwischen Zeile 25 und 26 einfügen:
If %Cnt% GTR 3 Del %1 & Goto :Eof
Bitte warten ..
Mitglied: jo4884
14.04.2010 um 14:04 Uhr
Danke für die schnelle Antwort, von der ich nicht viel Verstehe, aber leider funktioniert das bei mir
nicht .
Hab die Syntax von oben übernommen außer das ich in Zeile 3 und 4 meinen eigenen Pfad angegeben habe.
Wenn ich jetzt aus dem Command Window die .bat datei starte kommt eine Fehlermeldung das der Angegebene
Pfadname ungültig ist.
Was mach ich denn Falsch?

(Noch eine blöde Frage. Soll der obige Teil alles in eine einzelne bat-Datei?)

Gruß
Bitte warten ..
Mitglied: LotPings
14.04.2010 um 14:26 Uhr
Hallo jo,

habe es nochmal auf einem anderen PC getestet, es geht.

Du mußt den kompletten Text in eine Datei mit der Endung .bat oder .cmd kopieren und speichern.
Zum Test empfiehlt sich der Aufruf aus einem geöffneten CMD Fenster oder der Einbau von einem Pause Befehl zwischen Zeile 07 und 08.

Zur Erläuterung:
Zeile 6 übergibt alle gefundenen Dateien an die Subroutine :proc.
In proc wird :
- der Zielpfad gebildet (12) und
- geprüft ob er existiert - wenn nicht wird er eingerichtet (13)
- geprüft ob eine Datei des Namens existiert, wenn ja die Subroutine VersionInc aufgerufen.
wenn nicht der move ausgeführt.
In VersionInc wird
- der Dateiname von der ggfs vorhanden Nr separiert und die Nr erhöht.
- wenn der neue Name schon da ist, ruft die Subroutine sich mit diesem neuen Namen selbst (rekursiv) auf.
- die Datei mit der neuen Nr umbenannt.

Gruß
LotPings
Bitte warten ..
Mitglied: jo4884
14.04.2010 um 15:11 Uhr
Ich seh nur noch ?????. Vielleicht siehst du ja ob ich mir selbst ein ei ins Nest gelegt hab.

wenn ich es über ein Cmd Fenster öffne kommt folgender Fehler :

----"U:\Move\Input\A\test.txt"
Der Angegebene Pfadname ist ungültig.
Move "U:\Move\Input\A\test.txt" "Var:=U:\Move\Work"
Der Angegebene Pfadname ist ungültig.


::Move.bat::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off & setlocal EnableDelayedExpansion
Set SrcFld=U:\Move\Input
Set DstFld=U:\Move\Work
Pushd "%SrcFld%"
For /f "Delims=" %%A in ('Dir /B/S/A-D *') Do Call :Proc "%%~fA"
Popd
Goto :Eof
:Proc
echo ---- %1
Set "Var=%~dp1"
Set "DestPath=!Var:%ScrFld%=%DstFld%!"
If Not Exist "%DestPath%" MD "%DestPath%"
Set "Dest=%DestPath%%~nx1"
If Exist "%Dest%" Call:VersionInc "%Dest%"
echo Move %1 "%DestPath%"
Move %1 "%Dest%" >NUL
Goto :Eof
:VersionInc %1
Setlocal
Set Cnt=0
For /F "Tokens=1,2 delims=_" %%B in ("%~n1") Do (
Set Name %%B
Set /A Cnt=%%C+1
)
Set "NewName=%Name%_%Cnt%%~x1"
If Exist "%~dp1%NewName%" Call :VersionInc "%~dp1%NewName%"
Echo Ren %1 "%NewName%"
Ren %1 "NewName%"
Goto :Eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Bitte warten ..
Mitglied: LotPings
14.04.2010 um 15:38 Uhr
Hallo Jo,

kopieren heißt nicht selber engeben,
dabei passieren nämlich schon mal Buchstabendreher/Fehler wie du einiege eingebaut hast.
Zeile 12 SrcFld nicht ScrFld
Zeile 23 fehlt das Gleichheitszeichen.
Zeile 29 fehlt ein % vor NewName.

Außerdem wird der von dir gepostete Code besser lesbar wenn du die Tags we in der Formatierungshilfe angegeben verwendest.

Gruß
LotPings
Bitte warten ..
Mitglied: jo4884
14.04.2010 um 15:50 Uhr
Ich Danke Dir. Du bist mein Held.
Jetzt funktioniert es. Bin dir echt Dankbar,
auch für die Erläuterungen zwischendurch.
Die sind sehr Hilfreich fürs Verständnis.

Gruß und Dank

Jo
Bitte warten ..
Ähnliche Inhalte
Batch & Shell
gelöst Batch Datei: PDF Dateien verschieben, umbenennen und löschen (4)

Frage von F0rcehunter zum Thema Batch & Shell ...

Windows 7
gelöst Dateien verschieben Sicheheitswarnung Aktivieren (1)

Frage von Krabbelfiechle zum Thema Windows 7 ...

Batch & Shell
gelöst PS: zugehörige Import-Dateien ins Verzeichnis der Log-Dateien verschieben (4)

Frage von Jenny82 zum Thema Batch & Shell ...

Neue Wissensbeiträge
Windows 10

Windows 8.x oder 10 Lizenz-Key aus dem ROM auslesen mit Linux

(6)

Tipp von Lochkartenstanzer zum Thema Windows 10 ...

Tipps & Tricks

Wie Hackt man sich am besten in ein Computernetzwerk ein

(40)

Erfahrungsbericht von Herbrich19 zum Thema Tipps & Tricks ...

Heiß diskutierte Inhalte
Windows 10
gelöst Windows 10 Home "Netzlaufwerk nicht bereit" (19)

Frage von Oggy01 zum Thema Windows 10 ...

Exchange Server
gelöst RU 17 Exchange 2010 . Erfahrungen? (10)

Frage von keine-ahnung zum Thema Exchange Server ...

Datenbanken
gelöst MySQL Zeiterfassungs-Problematik (wer ist eingecheckt) (9)

Frage von NativeMode zum Thema Datenbanken ...

Windows Server
Festplatten Ruhezustand Windows Server 2016 (8)

Frage von ahaeuser zum Thema Windows Server ...