sommerzeit
Goto Top

Verzeichnisse mit batch erstellen

Hallo kann bitte jemand helfen,

Ich würde gerne per Batch-Datei (ImageMagick) aus meinen PDFs, Thumbnail-Bilder machen, vorher soll in jeden Ordner (unterhalb eines bestimmten Verzeichnisses!) ein Ordner „thumbs“ angelegt werden, in den die JPGs dann gelegt werden.

Das Konvertieren und das Ablegen klappt eigentlich auch.
Nur habe ich das Problem, das hierdurch auch unter (z.B.) „C“ ein Ordner „thumbs“ angelegt wird und die Verarbeitung eines dort zufällig liegenden (anderen) PDFs ebenfalls versucht wird.

Ich möchte aber wirklich nur die PDFs verarbeitet haben, die in verschiedenen Unterodnern unter meinem bestimmten „PDF-Verzeichnis“ (z.B. C:\test\PDF) liegen.
Und auch nur in denen die „thumbs“Ordner erstellt haben.

Kann mir hierbei bitte jemand weiterhelfen.
Danke.

Hier mein momentaner Stand:


@for /f "delims=" %%i in ('dir /ad/s/b') do @call :create %%i %%~ni

:create
@if "%2"=="thumbs" goto :eof

@if not exist %1\thumbs mkdir %1\thumbs
@for %%b in (%1\*.pdf) do @call :convert %1 %%b
@goTo :eof

:convert
convert -resize 73x98 "%2" "%1\thumbs\%~n2.jpg"

@goTo :eof


Vielen Dank

Content-Key: 124678

Url: https://administrator.de/contentid/124678

Ausgedruckt am: 28.03.2024 um 13:03 Uhr

Mitglied: Dipps
Dipps 10.09.2009 um 16:22:12 Uhr
Goto Top
wie wäre es mit
mkdir Verzeichniss
mkdir c:\test\temp 
das Verzeichniss anzulegen? und mit rd kannst du es wieder löschen
Mitglied: bastla
bastla 10.09.2009 um 16:23:10 Uhr
Goto Top
Hallo sommerzeit!

Soferne ich das richtig interpretiere, müsstest du doch nur das Startverzeichnis angeben:
@for /f "delims=" %%i in ('dir /ad/s/b C:\test\PDF') do @call :create %%i %%~ni
Grüße
bastla
Mitglied: 77559
77559 10.09.2009 um 16:33:07 Uhr
Goto Top
Hallo sommerzeit,

die erste for Schleife ist doch eigentlich überflüssig.

So sollte es doch gehen:
@Echo off
Set "Base=C:\Test\PDf"  
Pushd "%Base%"  
for /f "delims=" %%i in (  
   'dir /B/B/A-D "*.pdf" '  
  ) Do call :convert "%%~dpi\thumbs" "%%~fi"  
Popd
Goto :eof
:convert
if not exist %1 MD %1
convert -resize 73x98 "%2" "%~1\%~n2.jpg"  
goto :eof

ungetestet

Gruß
LotPings
Mitglied: sommerzeit
sommerzeit 11.09.2009 um 08:45:26 Uhr
Goto Top
Hallo bastla und LotPings,

vielen Dank für die schnellen Antworten.
Leider hat Beides nicht so ganz hingehauen.

@bastla:
Der Grundgedanken mit dem Startverzeichnis ist korrekt.
Ich habe dies auch so probiert, leider legt mir das Batch trotzdem unter „C:“ ebenfalls den Ordner „thumbs“ an und versucht ein (nicht zugehöriges) PDF, das zufällig auf C liegt zu verarbeiten: (s.letzte Meldung):

Hier wird das Letzte der zugehörigen PDFs (im letzten Unterordner) noch sauber abgearbeitet:

C:\test\PDF>convert -resize 73x98 "C:\test\PDF\Unterordner2\Test-pdf_0040.pdf" "C:\test\PDF\Unterorder2\thumbs\Test-pdf_0040.jpg"

Und hier wird dann anschließend noch versucht ein anderes PDF -das auf C liegt- ebenfalls zu verarbeiten:

C:\test\PDF>convert -resize 73x98 "" "\seite1.pdf\thumbs\.jpg"
convert: missing an image filename `\seite1.pdf\thumbs\.jpg' @ convert.c/Convert
ImageCommand/2775.


@77559:
Das sieht auch gut aus, aber hier habe ich das Problem, das nur in einem Unterordner (den ich angeben muss und in dem PDFs liegen müssen) die Verarbeitung hinhaut (und auch nur dann dort ein„thumbs“-Ordner dazu angelegt wird). Ich möchte aber, das dies in allen Subdirectories –von einem Masterdirectory ausgehend- geschieht (daher muss ich doch eine For Schleife einbauen, oder ?)…

Vielen Dank
Gruß sommerzeit
Mitglied: bastla
bastla 11.09.2009 um 10:27:44 Uhr
Goto Top
Hallo sommerzeit!

Hatte leider nur kurz drübergeschaut und übersehen, dass vor der Zeile
:create
eine Zeile
goto :eof
fehlt - dadurch wird das Unterprogramm ":create" nach dem Durchlaufen aller passenden Ordner ein letztes Mal aufgerufen, und da %1 zu diesem Zeitpunkt keinen Inhalt hat in weiterer Folge
for %%b in (\*.pdf) do @call :convert %1 %%b
ausgeführt, was dann natürlich wegen des "\" am Anfang "C:\" bearbeitet.
LotPings Variante müsste übrigens in Zeile 5 geringfügig verändert werden:
'dir /S/B/A-D "*.pdf" '
Grüße
bastla
Mitglied: sommerzeit
sommerzeit 11.09.2009 um 11:45:26 Uhr
Goto Top
Hallo Bastla und LotPings,

vielen herzlichen Dank, beide Lösungen funktionieren PERFEKT.
Mitglied: 77559
77559 11.09.2009 um 16:11:18 Uhr
Goto Top
Zitat von @bastla:
LotPings Variante müsste übrigens in Zeile 5
geringfügig verändert werden:
'dir /S/B/A-D "*.pdf" '
> 

Hallo bastla,
Danke für die Korrektur!

Gruß
LotPings
Mitglied: bastla
bastla 11.09.2009 um 16:52:34 Uhr
Goto Top
@77559
Ich glaube, ich schulde Dir noch einige mehr ... face-wink

Grüße
bastla