Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

XML Dateien in Verzeichnis auslesen, Prüfung von Datum, Verschieben von XML Datei

Frage Entwicklung Batch & Shell

Mitglied: Crol1234

Crol1234 (Level 1) - Jetzt verbinden

09.01.2012 um 21:28 Uhr, 3770 Aufrufe, 9 Kommentare

Hallo Forengemeinde!,

Ich brauche eine Lösung für mein kleines Problem und bin mit meinen bescheidenen Kenntnissen am Ende....

Ich habe ein Ordner mit folgendem Pfad: D:/ORDNER
In diesem Ordner sind einige XML Dateien.
Ich möchte 2 Werte aus den XML Dateien auslesen:

<ContentTitleText>TITEL</ContentTitleText>

sowie

<ContentKeysNotValidAfter>2012-01-20T00:00:00+01:00</ContentKeysNotValidAfter>


DIese beiden Werte hätte ich gern in eine (TEXT)Datei geschrieben, für jede XML eine Zeile:

TITEL 2012-01-20T00:00:00+01:00
TITEL 2012-01-20T00:00:00+01:00

usw.. Die Werte unterscheiden sich natürlich.

Als Krönung müsste das Script das aktuelle Datum mit dem jeweiligen Datum aus der XML vergleichen (möglichst Sekundengenau) und falls das heutige Datum später ist als der Wert, die XML Datei aus die der Wert stammt in das Verzeichnis D:/ORDNER/alt

verschieben....

Ich bin zu diesem Thema schon auf folgenden Beitrag gestoßen:
http://www.administrator.de/index.php?content=141792

komme aber nicht wirklich weiter, auch weiß ich nicht ob Powershell oder batch oder wie auch immer am sinnvollsten ist?...

Die Datei möchte ich immer wieder aufrufen, um so ein weiteres füllen der Textdatei(o.ä.) und verschieben der xml dateien zu erwirken.

Ich hoffe das ist nicht unmöglich mit vertretbarem Aufwand?..

Vielen Dank im voraus!
Mitglied: bastla
09.01.2012 um 21:58 Uhr
Hallo Crol1234 und willkommen im Forum!

Soferne der Batch nicht auch die Zeitzone ermitteln soll und die entsprechenden Zeilen in der XML-Datei Deinen Beispielen entsprechen, könnte das so gehen:
01.
@echo off & setlocal 
02.
set "Quelle=D:\ORDNER" 
03.
set "Dateien=*.xml" 
04.
set "Ziel=D:\ORDNER\alt" 
05.
set "Log=D:\ORDNER\XML-Log.txt" 
06.
 
07.
pushd "%Ordner%" 
08.
for /f "delims=" %%i in ('dir /b %Dateien%') do call :ProcessFile "%%i" 
09.
popd 
10.
goto :eof 
11.
 
12.
:ProcessFile 
13.
for /f "tokens=2 delims=<>" %%a in ('findstr "<ContentTitleText>" %1') do set "Titel=%%a" 
14.
for /f "tokens=2 delims=<>" %%a in ('findstr "<ContentKeysNotValidAfter>" %1') do set "Datum=%%a" 
15.
setlocal enabledelayedexpansion 
16.
>>"%Log%" echo %Titel% %Datum% 
17.
endlocal 
18.
 
19.
for /f "tokens=1-3 delims=." %%a in ("%date%") do set "Jetzt=%%c-%%b-%%aT%time:~,8%+01:00" 
20.
set "Jetzt=%Jetzt: =0%" 
21.
 
22.
if "%Jetzt%" gtr "%Datum%" ( 
23.
    md "%Ziel%" 2>nul 
24.
    move %1 "%Ziel%" 
25.
26.
goto :eof
Grüße
bastla

[Edit] Noch Vorsorge für ev im Titel enthaltene Sonderzeichen getroffen [/Edit]
Bitte warten ..
Mitglied: Crol1234
09.01.2012 um 22:06 Uhr
Vielen Dank für die super schnelle Möglichkeit!

Ist es unerheblich wo die zwei zu suchenden Parameter sind? Also in welcher Zeile? Ich bin mir nicht sicher ob der Aufbau der XML immer gleich ist. Ich weiß nur dass die zu suchenden Parameter definitiv irgendwo vorhanden sind....

Das mit der Zeitzone hatte ich ganz vergessen... Starke Verkomplizierung?


ok Probleme:

in der Log Datei steht:
ContentTitleText ContentKeysNotValidAfter
ContentTitleText ContentKeysNotValidAfter

aber quasi nicht der Inhalt....

und wenn ich die Batch nochmal ausführe, dann habe ich alle Einträge doppelt... Eine Ergänzung wäre sinnvoll, oder ich lösche die LOG per Hand immer wieder...

[/EDIT] Man könnte ja die Log vor jedem Schreiben erst leeren [/EDIT]
Bitte warten ..
Mitglied: bastla
09.01.2012 um 22:42 Uhr
Hallo Crol1234!
Das mit der Zeitzone hatte ich ganz vergessen... Starke Verkomplizierung?
Dafür musste ich noch etwas bei Richard L. Mueller borgen:
01.
@echo off & setlocal 
02.
set "Quelle=D:\ORDNER" 
03.
set "Dateien=*.xml" 
04.
set "Ziel=D:\ORDNER\alt" 
05.
set "Log=D:\ORDNER\XML-Log.txt" 
06.
 
07.
del "%Log%" 2>nul 
08.
 
09.
set G=%temp%\GetBias.vbs 
10.
 >%G% echo 'http://www.rlmueller.net/Programs/Integer8Date.txt 
11.
>>%G% echo lngBiasKey=CreateObject("Wscript.Shell").RegRead("HKLM\System\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias") 
12.
>>%G% echo If (UCase(TypeName(lngBiasKey))="LONG") Then:lngBias=lngBiasKey:Else:If (UCase(TypeName(lngBiasKey))="VARIANT()") Then:lngBias=0:For k=0 To UBound(lngBiasKey):lngBias=lngBias+(lngBiasKey(k)*256^^k):Next 
13.
>>%G% echo lngBias=lngBias/60:S="+":If lngBias^>0 Then S="-" 
14.
>>%G% echo WScript.Echo S^&Right("0"^&Abs(lngBias),2)^&":00" 
15.
for /f %%i in ('cscript //nologo %G%') do set "Bias=%%i" 
16.
 
17.
pushd "%Ordner%" 
18.
for /f "delims=" %%i in ('dir /b %Dateien%') do call :ProcessFile "%%i" 
19.
popd 
20.
goto :eof 
21.
 
22.
:ProcessFile 
23.
for /f "tokens=3 delims=<>" %%a in ('findstr "<ContentTitleText>" %1') do set "Titel=%%a" 
24.
for /f "tokens=3 delims=<>" %%a in ('findstr "<ContentKeysNotValidAfter>" %1') do set "Datum=%%a" 
25.
setlocal enabledelayedexpansion  
26.
>>"%Log%" echo %Titel% %Datum% 
27.
endlocal 
28.
 
29.
for /f "tokens=1-3 delims=." %%a in ("%date%") do set "Jetzt=%%c-%%b-%%aT%time:~,8%%Bias%" 
30.
set "Jetzt=%Jetzt: =0%" 
31.
 
32.
if "%Jetzt%" gtr "%Datum%" ( 
33.
    md "%Ziel%" 2>nul 
34.
    move %1 "%Ziel%" 
35.
36.
goto :eof
[Edit] Habe Dein "Edit" erst jetzt gesehen ...

Log-File wird gelöscht;
wenn der Logfile-Inhalt
ContentTitleText ContentKeysNotValidAfter 
ContentTitleText ContentKeysNotValidAfter
ist, sollte eine Änderung des Tokens auf 3 (ist in dieser Version bereits durchgeführt) genügen - Ursache sind vermutlich Leerzeichen am Beginn der jeweiligen XML-Zeile ...
[/Edit]

Grüße
bastla
Bitte warten ..
Mitglied: Crol1234
09.01.2012 um 22:50 Uhr
Was soll ich sagen, das ist einfach genial!!! Es funktioniert...

Ich danke dir vielmals!!!
Bitte warten ..
Mitglied: Crol1234
09.01.2012 um 22:51 Uhr
ach ganz wichtig:

DIe XML wird niemals verändert? Das ist absolut wichtig!

Kann ich die Ausgabe in die Textdatei noch anders gestalten?

Das Datum ist so noch schlecht lesbar, kann man das in einem anderen Format anzeigen? zB: TT-MM-JJJJ 00:00:00


[EDIT] Mir ist was unglückliches aufgefallen, "alte" Dateien die verschoben werden sollten nicht in dem LOGfile auftauchen [/EDIT]
Bitte warten ..
Mitglied: bastla
09.01.2012 um 22:58 Uhr
Hallo Crol1234!

Noch etwas verbessert (es sollten jetzt die Werte immer dann gefunden werden, wenn in der Zeile vor zB "<ContentTitleText>" kein zusätzliches "<" oder ">" enthalten ist):
01.
@echo off & setlocal 
02.
set "Quelle=D:\ORDNER" 
03.
set "Dateien=*.xml" 
04.
set "Ziel=D:\ORDNER\alt" 
05.
set "Log=D:\ORDNER\XML-Log.txt" 
06.
 
07.
del "%Log%" 2>nul 
08.
 
09.
set G=%temp%\GetBias.vbs 
10.
 >%G% echo 'http://www.rlmueller.net/Programs/Integer8Date.txt 
11.
>>%G% echo lngBiasKey=CreateObject("Wscript.Shell").RegRead("HKLM\System\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias") 
12.
>>%G% echo If (UCase(TypeName(lngBiasKey))="LONG") Then:lngBias=lngBiasKey:Else:If (UCase(TypeName(lngBiasKey))="VARIANT()") Then:lngBias=0:For k=0 To UBound(lngBiasKey):lngBias=lngBias+(lngBiasKey(k)*256^^k):Next 
13.
>>%G% echo lngBias=lngBias/60:S="+":If lngBias^>0 Then S="-" 
14.
>>%G% echo WScript.Echo S^&Right("0"^&Abs(lngBias),2)^&":00" 
15.
for /f %%i in ('cscript //nologo %G%') do set "Bias=%%i" 
16.
 
17.
pushd "%Ordner%" 
18.
for /f "delims=" %%i in ('dir /b %Dateien%') do call :ProcessFile "%%i" 
19.
popd 
20.
goto :eof 
21.
 
22.
:ProcessFile 
23.
for /f "delims=" %%a in ('findstr "<ContentTitleText>" %1') do set "Zeile=%%a" 
24.
set /a Token=2 
25.
if "%Zeile:~,1%" neq "<" set /a Token=3 
26.
for /f "tokens=%Token% delims=<>" %%a in ("%Zeile%") do set "Titel=%%a" 
27.
 
28.
for /f "delims=" %%a in ('findstr "<ContentKeysNotValidAfter>" %1') do set "Zeile=%%a" 
29.
set /a Token=2 
30.
if "%Zeile:~,1%" neq "<" set /a Token=3 
31.
for /f "tokens=%Token% delims=<>" %%a in ("%Zeile%") do set "Datum=%%a" 
32.
for /f "tokens=1-4 delims=T+-" %%a in ("%Datum%") do set "DatumAusgabe=%%c-%%b-%%a %%d" 
33.
 
34.
for /f "tokens=1-3 delims=." %%a in ("%date%") do set "Jetzt=%%c-%%b-%%aT%time:~,8%%Bias%" 
35.
set "Jetzt=%Jetzt: =0%" 
36.
 
37.
if "%Jetzt%" gtr "%Datum%" ( 
38.
    md "%Ziel%" 2>nul 
39.
    move %1 "%Ziel%" 
40.
) else ( 
41.
    setlocal enabledelayedexpansion  
42.
    >>"%Log%" echo %Titel% %DatumAusgabe% 
43.
    endlocal 
44.
45.
goto :eof
DIe XML wird niemals verändert? Das ist absolut wichtig!
Die Datei wird nur gelesen und im Fall des Falles verschoben - der Inhalt bleibt unverändert ...

[Edit] Schreiben in Log vom Alter abhängig gemacht, Datumsausgabe - nochmals um 23:09 - angepasst [Edit2] und in Zeile 32 korrigiert [/Edit2] [/Edit]

Grüße
bastla
Bitte warten ..
Mitglied: Crol1234
09.01.2012 um 23:16 Uhr
jetzt wird das Datum nichtmehr in der Datei angezeigt
Bitte warten ..
Mitglied: bastla
09.01.2012 um 23:21 Uhr
Hallo Crol1234!

Sorry - durch das Editieren gab's einen ":" zuviel - ist oben (in Zeile 32) korrigiert ...

Grüße
bastla
Bitte warten ..
Mitglied: Crol1234
09.01.2012 um 23:27 Uhr
perfekt ! Jetzt klappt alles so wie ich es mir erträumt habe
Bitte warten ..
Neuester Wissensbeitrag
Windows 10

Powershell 5 BSOD

(8)

Tipp von agowa338 zum Thema Windows 10 ...

Ähnliche Inhalte
Batch & Shell
gelöst EDI Dateien auf Inhalt prüfen und verschieben (6)

Frage von ThomasKern zum Thema Batch & Shell ...

Batch & Shell
gelöst Ordner per Batch verschieben, Datei kopieren (2)

Frage von Shape.Shifter zum Thema Batch & Shell ...

Batch & Shell
gelöst 2 große TXT Dateien vergleichen und Unterschiede in andere Datei schreiben (6)

Frage von sid.pdm zum Thema Batch & Shell ...

Heiß diskutierte Inhalte
Microsoft
Ordner mit LW-Buchstaben versehen und benennen (21)

Frage von Xaero1982 zum Thema Microsoft ...

Netzwerkmanagement
gelöst Anregungen, kleiner Betrieb, IT-Umgebung (18)

Frage von Unwichtig zum Thema Netzwerkmanagement ...

Windows Update
Treiberinstallation durch Windows Update läßt sich nicht verhindern (17)

Frage von liquidbase zum Thema Windows Update ...