Top-Themen

Aktuelle Themen (A bis Z)

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit

XML Parameter auslesen und in CSV überführen

Frage Entwicklung Batch & Shell

Mitglied: Crol1234

Crol1234 (Level 1) - Jetzt verbinden

11.01.2012, aktualisiert 16.02.2012, 3405 Aufrufe, 19 Kommentare, 1 Danke

Hallo zusammen,

Ich habe folgendes Problem:

Ich habe eine XML Datei im Internet auf die komme ich über http://........de/file.xml heran.und - Ja ich darf das, ja es ist meine Datei (kann natürlich aber auch ein lokaler Pfad sein wobei wenn ich sie übers Internet aufrufe aktueller ist)

Den für mich interessanten Aufbau der Datei lautet wie folgt (da steht aber nicht nur das, sondern noch anderes Zeugs drin)
01.
<PerformanceList> 
02.
03.
04.
05.
06.
<Performance FilmTitle="FILM" PerformanceTitle="Wert1" PerformanceOID="blablabla" FilmOID="blablabla" CenterOID="blablabla" PerformanceEDINumber="blablabla" PerformanceTyp="0" PerformanceDate="20120111" CinemaDay="blablabla" AuditoriumName="blablabla" AuditoriumNo="blablabla" AuditoriumOID="blablabla" WeekPlayed="blablabla" StartTime="2300" EndTime="0100" NominatedSeats="blablabla" Rating="12" NationwideStartDate="blablabla" TicketingLink="blablabla" FilmSeries="" SoundSystem="blablabla" PictureFormat="" SortOrderPrio="0" TimeStamp="5" CUSTOMFIELDSWEEKFILM="" CUSTOMFIELDSPERFORMANCE="" OCCUPATIONINFO="0"/> 
07.
08.
09.
10.
11.
</PerformanceList>
WIe ihr sehen könnt geht es um Filme, dieser Block wiederholt sich pro Vorstellung.

Ich möchte folgende Werte pro Zeile in eine CSV oder in eine txt... (egal) übergeben: Für jeden Block dann quasi wieder eine neue Zeile....

In dieser Reihenfolge (wobei wenn das zusätzlich kompliziert ist, auch egal)
01.
PerformanceDate;StartTime;Endtime;PerformanceTitle;Rating (1. Block) 
02.
PerformanceDate;StartTime;Endtime;PerformanceTitle;Rating  (2. Block) 
03.
PerformanceDate;StartTime;Endtime;PerformanceTitle;Rating usw... 
04.
usw...
Ich bin hier schon auf den Beitrag gestoßen aber irgendwie will es nicht klappen:

http://www.administrator.de/index.php?content=156962


Danke, Grüße Crol1234
Mitglied: rubberman
11.01.2012 um 16:11 Uhr
Hallo Crol1234,

das ist mit Batch eher suboptimal. VBS bietet über das XML DOM Object eine recht gute Alternative. Dazu müsstest du folgendes prüfen/mitteilen:
- ist die XML Datei in einem gültigen Format? (stimmt das im Kopf angegebene Encoding mit dem Inhalt überein, gibt es ungültige Zeichen im Text etc.)
- Wie sieht die Struktur der XML aus? (unter welchem Pfad finden sich die PerformanceList Elemente)

Grüße
rubberman
Bitte warten ..
Mitglied: Crol1234
11.01.2012 um 16:23 Uhr
Hallo rubberman,

also ich versuche mitzukommen,

die datei hat folgenden anfang <?xml version="1.0" encoding="ISO-8859-1"?>
und es befinden sich u.a. "ü" oder "&" im Text

Der Aufbau sieht wie folgt aus:
01.
<?xml version="1.0" encoding="ISO-8859-1"?> 
02.
-<WebInfo CreationTime="20120111152034" Installation="xxx" Version="1.4"> 
03.
<Centerlist> 
04.
<Center...... /> 
05.
</Centerlist> 
06.
<Filmlist> 
07.
<Film......../> 
08.
<Centersplayed> 
09.
<CenterOID "......:" /> 
10.
</Centersplayed> 
11.
12.
13.
14.
15.
</Filmlist> 
16.
<PerformanceList> 
17.
<Performance "...... " /> 
18.
19.
20.
21.
</PerformanceList> 
22.
</Webinfo>
Bitte warten ..
Mitglied: rubberman
11.01.2012 um 16:41 Uhr
Hallo Crol1234,

Umlaute und ß wären grundsätzlich für Encoding ISO-8859-1 in Ordnung. Bin noch auf Arbeit, werde mir das Ganze zu Hause zu Gemüte führen.
Ähnlich: Diese Geschichte. Da allerding als HTA mit Javascript.

Grüße
rubberman
Bitte warten ..
Mitglied: Crol1234
11.01.2012 um 16:43 Uhr
gut damit kann ich jetzt garnix anfangen ,, mir geht es nur darum dass ich irgendwie was ausführbares brauch wo man jetzt nicht irgendwelche umgebungen installieren muss?
wie das umgesetzt ist , ist eigentlich egal.
Bitte warten ..
Mitglied: rubberman
11.01.2012 um 19:11 Uhr
Hallo Crol1234.

[...] mir geht es nur darum dass ich irgendwie was ausführbares brauch [...] wie das umgesetzt ist , ist eigentlich egal.

Also "RentACoder.com" ist zwar eine andere Webseite, aber da ich es nun schon angeboten habe... Teste:

*.vbs
01.
Const sXMLURL = "http://www.forumoffenburg.de/texxas.xml" 
02.
Const sCSVPath = "test.csv" 
03.
Const sDelim = ";" 
04.
 
05.
 
06.
Set oXMLHTTP = CreateObject("MSXML2.XMLHTTP") 
07.
oXMLHTTP.Open "GET", sXMLURL, False 
08.
oXMLHTTP.Send 
09.
If (oXMLHTTP.readyState = 4 And oXMLHTTP.status = 200) Then 
10.
  Set oXmlDoc = CreateObject("MSXML2.DOMDocument") 
11.
  oXmlDoc.async = False 
12.
  oXmlDoc.validateOnParse = False 
13.
  oXmlDoc.resolveExternals = False 
14.
  Set oADOStream = CreateObject("ADODB.Stream") 
15.
  With oADOStream 
16.
    .Type = 1 
17.
    .Mode = 3 
18.
    .Open 
19.
    .Write oXMLHTTP.responseBody 
20.
    .Position = 0 
21.
    .Type = 2 
22.
    .CharSet = "ISO-8859-1" 
23.
    oXmlDoc.loadXML .ReadText 
24.
    .Close 
25.
  End With 
26.
  Set oADOStream = Nothing 
27.
End If 
28.
Set oXMLHTTP = Nothing 
29.
 
30.
Set oPerfList = oXmlDoc.documentElement.selectSingleNode("//PerformanceList") 
31.
For Each oPerf In oPerfList.childNodes 
32.
  txt = txt & oPerf.getAttribute("PerformanceDate") & sDelim & _ 
33.
    oPerf.getAttribute("StartTime") & sDelim & _ 
34.
    oPerf.getAttribute("EndTime") & sDelim & _ 
35.
    oPerf.getAttribute("PerformanceTitle") & sDelim & _ 
36.
    oPerf.getAttribute("Rating") & vbCrLf 
37.
Next 
38.
Set oPerfList = Nothing 
39.
Set oXmlDoc = Nothing 
40.
 
41.
Set oFSO = CreateObject("Scripting.FileSystemObject") 
42.
Set oFile = oFSO.OpenTextFile(sCSVPath, 2, True) 
43.
oFile.Write txt 
44.
oFile.Close 
45.
Set oFile = Nothing 
46.
Set oFSO = Nothing 
47.
 
48.
MsgBox "CSV erstellt", vbInformation, "Fertig"
Grüße
rubberman
Bitte warten ..
Mitglied: Crol1234
11.01.2012 um 19:18 Uhr
funktioniert gut, kleinigkeit: PerformanceTitle wird abgeschnitten nach einer gewissen Anzahl an Buchstaben.
Kann man die Zeiten noch durch ein : trennen?

Kann man eine Sortierung stattfinden lassen zuerst nach Datum und dann Nach Starttime?
Bitte warten ..
Mitglied: rubberman
11.01.2012 um 19:31 Uhr
Hallo Crol1234.

funktioniert gut, kleinigkeit: PerformanceTitle wird abgeschnitten nach einer gewissen Anzahl an Buchstaben.
Schau mal in deine XML. Wolltest du lieber das Attribut FilmTitle?

Kann man die Zeiten noch durch ein : trennen?
Kann man.

Kann man eine Sortierung stattfinden lassen zuerst nach Datum und dann Nach Starttime?
Excel?

01.
Const sXMLURL = "http://www.forumoffenburg.de/texxas.xml" 
02.
Const sCSVPath = "test.csv" 
03.
Const sDelim = ";" 
04.
 
05.
 
06.
Set oXMLHTTP = CreateObject("MSXML2.XMLHTTP") 
07.
oXMLHTTP.Open "GET", sXMLURL, False 
08.
oXMLHTTP.Send 
09.
If (oXMLHTTP.readyState = 4 And oXMLHTTP.status = 200) Then 
10.
  Set oXmlDoc = CreateObject("MSXML2.DOMDocument") 
11.
  oXmlDoc.async = False 
12.
  oXmlDoc.validateOnParse = False 
13.
  oXmlDoc.resolveExternals = False 
14.
  Set oADOStream = CreateObject("ADODB.Stream") 
15.
  With oADOStream 
16.
    .Type = 1 
17.
    .Mode = 3 
18.
    .Open 
19.
    .Write oXMLHTTP.responseBody 
20.
    .Position = 0 
21.
    .Type = 2 
22.
    .CharSet = "ISO-8859-1" 
23.
    oXmlDoc.loadXML .ReadText 
24.
    .Close 
25.
  End With 
26.
  Set oADOStream = Nothing 
27.
End If 
28.
Set oXMLHTTP = Nothing 
29.
 
30.
Set oPerfList = oXmlDoc.documentElement.selectSingleNode("//PerformanceList") 
31.
For Each oPerf In oPerfList.childNodes 
32.
  txt = txt & oPerf.getAttribute("PerformanceDate") & sDelim & _ 
33.
    Left(oPerf.getAttribute("StartTime"), 2) & ":" & Right(oPerf.getAttribute("StartTime"), 2) & sDelim & _ 
34.
    Left(oPerf.getAttribute("EndTime"), 2) & ":" & Right(oPerf.getAttribute("EndTime"), 2) & sDelim & _ 
35.
    oPerf.getAttribute("FilmTitle") & sDelim & _ 
36.
    oPerf.getAttribute("Rating") & vbCrLf 
37.
Next 
38.
Set oPerfList = Nothing 
39.
Set oXmlDoc = Nothing 
40.
 
41.
Set oFSO = CreateObject("Scripting.FileSystemObject") 
42.
Set oFile = oFSO.OpenTextFile(sCSVPath, 2, True) 
43.
oFile.Write txt 
44.
oFile.Close 
45.
Set oFile = Nothing 
46.
Set oFSO = Nothing 
47.
 
48.
MsgBox "CSV erstellt", vbInformation, "Fertig"
Grüße
rubberman
Bitte warten ..
Mitglied: Crol1234
11.01.2012 um 19:40 Uhr
hoppla, ja natürlich FilmTitle ist besser

wie kann ich noch am Anfang des Dokumentes

Datum;Startzeit;Endzeit;Saal;Filmtitel;FSK

ausgeben lassen?
Sonst hab ich in der Tabelle die Daten aus der ersten Zeile in der Tabellenüberschrift

und wie bekommt man das Sternchen bei manchen Filmtitle entfernt?
Bitte warten ..
Mitglied: rubberman
11.01.2012 um 19:56 Uhr
Hallo Crol1234.

Vor Zeile 30
txt = "Datum;Startzeit;Endzeit;Saal;Filmtitel;FSK" & vbCrLf
und wie bekommt man das Sternchen bei manchen Filmtitle entfernt?
Wie kommt es denn in die XML (lass es doch raus, wenn es schon deine eigene XML ist).

Grüße
rubberman
Bitte warten ..
Mitglied: Crol1234
11.01.2012 um 20:37 Uhr
die datei wird von unserem kassensystem erstellt. das kann ich so nicht beinflussen. da hängt zuviel dran.
Bitte warten ..
Mitglied: rubberman
11.01.2012 um 21:42 Uhr
Hallo Crol1234,

mit Sortierung und entfernten Sternchen:
01.
Const sXMLURL = "http://www.forumoffenburg.de/texxas.xml" 
02.
Const sCSVPath = "test.csv" 
03.
Const sDelim = ";" 
04.
 
05.
' Datentypen http://msdn.microsoft.com/en-us/library/windows/desktop/ms675318%28v=vs.85%29.aspx 
06.
Const adInteger = 3 ' Ganzzahl 
07.
Const adChar = 129 ' String 
08.
 
09.
' Streamtypen http://msdn.microsoft.com/en-us/library/windows/desktop/ms675277%28v=vs.85%29.aspx 
10.
Const adTypeBinary = 1 
11.
Const adTypeText = 2 
12.
 
13.
' Streammodus http://msdn.microsoft.com/en-us/library/windows/desktop/ms675792%28v=vs.85%29.aspx 
14.
Const adModeReadWrite = 3 
15.
 
16.
' Datei öffnen http://msdn.microsoft.com/en-us/library/314cz14s%28v=VS.85%29.aspx 
17.
Const ForWriting = 2 
18.
 
19.
' IXMLHTTPRequest http://msdn.microsoft.com/en-us/library/windows/desktop/ms760305%28v=vs.85%29.aspx 
20.
'  Download der Datei 
21.
Set oXMLHTTP = CreateObject("MSXML2.XMLHTTP") 
22.
oXMLHTTP.Open "GET", sXMLURL, False 
23.
oXMLHTTP.Send 
24.
If (oXMLHTTP.readyState = 4 And oXMLHTTP.status = 200) Then 
25.
  ' XML DOM http://msdn.microsoft.com/en-us/library/windows/desktop/ms764730%28v=vs.85%29.aspx 
26.
  '  Verarbeitung von XML Daten 
27.
  Set oXmlDoc = CreateObject("MSXML2.DOMDocument") 
28.
  oXmlDoc.async = False 
29.
  oXmlDoc.validateOnParse = False 
30.
  oXmlDoc.resolveExternals = False 
31.
  ' ADO Stream http://msdn.microsoft.com/en-us/library/windows/desktop/ms675032%28v=vs.85%29.aspx 
32.
  '  Konvertierung zur korrekten Zeichenkodierung 
33.
  Set oADOStream = CreateObject("ADODB.Stream") 
34.
  With oADOStream 
35.
    .Type = adTypeBinary 
36.
    .Mode = adModeReadWrite 
37.
    .Open 
38.
    .Write oXMLHTTP.responseBody 
39.
    .Position = 0 
40.
    .Type = adTypeText 
41.
    .CharSet = "ISO-8859-1" 
42.
    oXmlDoc.loadXML .ReadText 
43.
    .Close 
44.
  End With 
45.
  Set oADOStream = Nothing 
46.
End If 
47.
Set oXMLHTTP = Nothing 
48.
 
49.
Set oPerfList = oXmlDoc.documentElement.selectSingleNode("//PerformanceList") 
50.
' ADO Recordset http://msdn.microsoft.com/en-us/library/windows/desktop/ms681510%28v=vs.85%29.aspx 
51.
'  Virtuelle Datenbanktabelle zum Sortieren der Daten erstellen 
52.
Set oADORec = CreateObject("ADODB.Recordset") 
53.
oADORec.Fields.Append "Datum", adInteger 
54.
oADORec.Fields.Append "Startzeit", adChar, 5 
55.
oADORec.Fields.Append "Endzeit", adChar, 5 
56.
oADORec.Fields.Append "Saal", adInteger 
57.
oADORec.Fields.Append "Filmtitel", adChar, 1024 
58.
oADORec.Fields.Append "FSK", adInteger 
59.
oADORec.Open 
60.
arrFields = Array("Datum", "Startzeit", "Endzeit", "Saal", "Filmtitel", "FSK") 
61.
For Each oPerf In oPerfList.childNodes 
62.
  sDatum = oPerf.getAttribute("PerformanceDate") 
63.
  sStartzeit = Left(oPerf.getAttribute("StartTime"), 2) & ":" & Right(oPerf.getAttribute("StartTime"), 2) 
64.
  sEndzeit = Left(oPerf.getAttribute("EndTime"), 2) & ":" & Right(oPerf.getAttribute("EndTime"), 2) 
65.
  sSaal = oPerf.getAttribute("AuditoriumNo") 
66.
  sFilmtitel = oPerf.getAttribute("FilmTitle") 
67.
  If Left(sFilmtitel, 2) = "* " Then sFilmtitel = Mid(sFilmtitel, 3) 
68.
  sFSK = oPerf.getAttribute("Rating") 
69.
  arrValues = Array(sDatum, sStartzeit, sEndzeit, sSaal, sFilmtitel, sFSK) 
70.
  oADORec.AddNew arrFields, arrValues 
71.
Next 
72.
Set oPerfList = Nothing 
73.
Set oXmlDoc = Nothing 
74.
 
75.
oADORec.Sort = "Datum ASC, Startzeit ASC" 
76.
oADORec.MoveFirst 
77.
 
78.
' Daten der CSV zusammenstellen 
79.
txt = "Datum" & sDelim & "Startzeit" & sDelim & "Endzeit" & sDelim & "Saal" & sDelim & "Filmtitel" & sDelim & "FSK" & vbCrLf 
80.
While Not oADORec.EOF 
81.
  txt = txt & oADORec("Datum") & sDelim & _ 
82.
    oADORec("Startzeit") & sDelim & _ 
83.
    oADORec("Endzeit") & sDelim & _ 
84.
    oADORec("Saal") & sDelim & _ 
85.
    oADORec("Filmtitel") & sDelim & _ 
86.
    oADORec("FSK") & vbCrLf 
87.
    oADORec.MoveNext 
88.
Wend 
89.
oADORec.Close 
90.
Set oADORec = Nothing 
91.
 
92.
' FileSystemObject http://msdn.microsoft.com/en-us/library/d6dw7aeh%28v=VS.85%29.aspx 
93.
'  Schreiben der Daten in die CSV Datei 
94.
Set oFSO = CreateObject("Scripting.FileSystemObject") 
95.
Set oFile = oFSO.OpenTextFile(sCSVPath, ForWriting, True) 
96.
oFile.Write txt 
97.
oFile.Close 
98.
Set oFile = Nothing 
99.
Set oFSO = Nothing 
100.
 
101.
MsgBox "CSV erstellt", vbInformation, "Fertig"
Grüße
rubberman

<EDIT: Bibers Anregung folgeleistend - Konstanten und Kommentare ergänzt. />
Bitte warten ..
Mitglied: Biber
11.01.2012 um 23:23 Uhr
Moin rubberman,

einfach, pfiffig, nachvollziehbar und bei Bedarf auch von Nicht-Profis leicht anzupassen, deine Lösung.
Gefällt mir -sogar ohne Kommentarzeilen im Source sehr gut, und ich werde gleich einen entsprechenden Smiley setzen.

Könntest du mir und den sicherlich folgenden BeitragsfinderInnen noch - so quasi als kleinen Luxus - zwei Konstanten einbauen

01.
... 
02.
Const adInteger = 3 
03.
Const adChar = 129 
...und damit die Zeilen 33-38 etwas selbsterklärender machen?

So oder so ein danke von mir
Biber
Bitte warten ..
Mitglied: rubberman
12.01.2012 um 00:26 Uhr
Hallo Biber.

Gefällt mir -sogar ohne Kommentarzeilen im Source sehr gut, und ich werde gleich einen entsprechenden Smiley setzen.
Danke für die Blumen. Der Wink mit dem Zaunpfahl zwecks fehlender Kommentare ist angekommen

Könntest du mir und den sicherlich folgenden BeitragsfinderInnen noch - so quasi als kleinen Luxus - zwei Konstanten einbauen
Warum nur zwei? Mir fallen noch mehr nicht selbsterklärende Werte auf.

Oben entsprechend editiert ...

Grüße
rubberman
Bitte warten ..
Mitglied: Crol1234
12.01.2012 um 07:16 Uhr
einfach perfekt. Großes Lob für die aufgebrachte Mühe! wieder was gelernt...
Bitte warten ..
Mitglied: Crol1234
16.02.2012 um 14:27 Uhr
das skript lief lange zeit perfekt, bis heute: seitdem kommt der fehler:

Zeile 70
Zeichen: 3
Fehler: Die Argumente sind vom falschen Typ, liegen außerhalb des Gültigkeitsbereiches oder sind miteinander unvereinbar.
Code: 800A0BB9
Quelle: ADODB.Recordset
Bitte warten ..
Mitglied: Biber
17.02.2012 um 18:35 Uhr
Moin Crol1234,

ich bin ja kein Fachmann beim Interpretieren von Redmonder Fehlermeldungen.

Aber für mich hört es sich danach an, als würde in deiner Import-Datei ein nicht vorgesehener Wert durchschlagen.

Hast du denn mal überprüft, ob vielleicht in der XML-Datei (in der, mit der es abgeraucht ist) in einem Feld "Geburtsdatum" vielleicht "Augsburg" drinsteht o.ä.?

Grüße
Biber
Bitte warten ..
Mitglied: Crol1234
17.02.2012 um 19:03 Uhr
habe es gefunden, war ei ? in einem Feld für Zahlen und zwar FSK, wie mache ich das unempfindlich gegen Sonderzeichen oder Buchstaben?
Bitte warten ..
Mitglied: bastla
17.02.2012 um 21:04 Uhr
Hallo Crol1234!
wie mache ich das unempfindlich gegen Sonderzeichen oder Buchstaben?
Schau Dir doch mal die (inzwischen doch wirklich aussagekräftige formulierte) Zeile 58 und einige knapp davor an ...

Grüße
bastla
Bitte warten ..
Mitglied: rubberman
18.02.2012 um 18:00 Uhr
Hallo Crol1234.

In Zeile 5 abwärts habe ich die Konstanten für die Datentypen festgelegt. Diese findest du auf der dort angegebenen Seite im MSDN wieder. adChar (zusammen mit einer festgelegten Stringlänge) oder adVarChar wären hier wohl Typen, die man sinnvollerweise für alphanumerische Daten verwenden würde.

Grüße
rubberman
Bitte warten ..
Ähnliche Inhalte
Batch & Shell
XML in CSV umwandeln
gelöst Frage von jochengBatch & Shell2 Kommentare

Hallo Leute Ich habe folgende XML Datei die ich mit einem Batch in eine CSV umwandeln will. Mein Problem ...

Batch & Shell
Powershell xml zu csv
gelöst Frage von GeoSemBatch & Shell2 Kommentare

Hallo Dank einem Beitrag bin ich weiter gekommen ;-) Leider habe ich mit powershell keine Erfahrung - so habe ...

VB for Applications
Csv in xml umwandeln mit VBA
Frage von 130771VB for Applications8 Kommentare

Hallo zusammen, ich bin neu in der Commuity und auch neu im Bereich der Programmierung mit VBA. Ich habe ...

XML
CSV to XML Konverter
gelöst Frage von Tyga911XML6 Kommentare

Hallo zusammen, da das mein erster Beitrag ist, hoffe ich ich bin hier richtig mit meiner Fage. Und zwar ...

Neue Wissensbeiträge
Apple

IOS 11.2.1 stopft HomeKit-Remote-Lücke

Tipp von BassFishFox vor 17 StundenApple

Das Update für iPhone, iPad und Apple TV soll die Fernsteuerung von Smart-Home-Geräten wieder in vollem Umfang ermöglichen. Apple ...

Windows 10

Windows 10 v1709 EN murkst bei den Regionseinstellungen

Tipp von DerWoWusste vor 22 StundenWindows 10

Dieser kurze Tipp richtet sich an den kleinen Personenkreis, der Win10 v1709 EN-US frisch installiert und dabei die englische ...

Webbrowser

Kein Ton bei Firefox Quantum über RDP

Tipp von Moddry vor 22 StundenWebbrowser

Hallo Kollegen! Hatte das Problem, dass der neue Firefox bei mir auf der Kiste keinen Ton hat, wenn ich ...

Internet

EU-DSGVO: WHOIS soll weniger Informationen liefern

Information von sabines vor 1 TagInternet4 Kommentare

Wegen der europäische Datenschutzgrundverordnung stehen die Prozesse um die Registrierung von Domains auf dem Prüfstand. Sollte die Forderungen umgesetzt ...

Heiß diskutierte Inhalte
Windows Server
RODC kann nicht aus Domäne entfernt werden
Frage von NilsvLehnWindows Server18 Kommentare

HAllo, ich arbeite in einem Universitätsnetzwerk mit 3 Standorten. Die Standorte haben alle ein ESXi Cluster und auf diesen ...

Hardware
Links klick bei Maus funktioniert nicht
gelöst Frage von Pablu23Hardware16 Kommentare

Hallo erstmal. Ich habe ein Problem mit meiner relativ alten maus jedoch denke ich nicht das es an der ...

Windows XP
Windows XP Aktivieren geht nicht
Frage von tetikmiroWindows XP13 Kommentare

Hallo Ich habe einen Windows XP mit einen vCenter Converter umgezogen auf eine ESXI. Soweit funktioniert dies auch ohne ...

Netzwerkmanagement
Mehrere Netzwerkadapter in einem PC zu einem Switch zusammenfügen
gelöst Frage von prodriveNetzwerkmanagement12 Kommentare

Hallo zusammen Vorweg, ich konnte schon einige IT-Probleme mit Hilfe dieses Forums lösen. Wirklich klasse hier! Doch für das ...