Jul 03, 2007, updated at Jul 05, 2007 (UTC)

7375

Zeile nach gesuchter Zeile in Datei schreiben

Hallo zusammen!

Mit einer Batchdatei suche ich in einer Datei:
test.txt

unwichtig1
unwichtig2
suchwort
zeiledanach
unwichtig3

nach dem Wort "suchwort", und schreibe die Zeile in die datei "result.txt".
Alle anderen Zeilen schreibe ich in die Datei "andere.txt":

for /F "delims=" %%x in (c:\bat\test.txt) do call:doline "%%x"  
pause
goto:eof
:doline
set "line=%~1"  
if "%line:~0,20%" equ "suchwort" (  
echo %line%>>"c:\bat\result.txt"  
*****
) else (
echo %line%>>"c:\bat\andere.txt"  
)
goto:eof

Jetzt würde ich da wo die Sterne sind gerne einen Befehl einbauen der die "Zeile danach" in eine andere Datei schreibt.
Aber ich bekomme es irgendwie nicht hin

Grüße
Tobi

Please also mark the comments that contributed to the solution of the article

Content-Key: 62961

Url: https://administrator.de/contentid/62961

Printed on: April 16, 2024 at 21:04 o'clock

7 Comments

Latest comment

Hallo bufferm44!

Etwa so:

@echo off & setlocal
set Write=
for /F "delims=" %%x in (c:\bat\test.txt) do call:doline "%%x"  
pause
goto:eof
:doline
set "line=%~1"  
if "%line:~0,20%" equ "suchwort" (  
	set Write=True
	echo %line%>>"c:\bat\result.txt"  
) else (
	if not defined Write (
		echo %line%>>"c:\bat\andere.txt"	  
	) else (
		echo %line%>>"c:\bat\weitere.txt"  
		set Write=
	)
)
goto:eof

Grüße
bastla

Moin!

Guter Trick, die Idee hatte ich auch schon, hatte es mit der Syntax nicht hinbekommen. Im Printip funktioniert es wunderbar so. Da die auszulesende Zeile allerdings einen Haufen Sonderzeichen enthält, gibt es Probleme beim "set" der Variable.

Die "wichtige" Textzeile "danach" lautet beispielsweise:

12004X/Info eins)12:34/Infozwei:Info nummer drei(Infovier)/Infofünf(12-34)//Infosechs

Dabei kommt es zu folgendem Fehler:

C:\BAT>set "line=12004X/Info eins)12:34/Infozwei:Info nummer drei(Infovier)/Infofünf(12-34)//Infosechs"   

"12:34/Infozwei:Info" ist syntaktisch an dieser Stelle nicht verarbeitbar  

Gibt es hier noch einen Trick?

Vielen Dank!

Hallo bufferm44!

Versuch es vielleicht so:

@echo off & setlocal
set Write=
for /F "delims=" %%x in (c:\bat\test.txt) do (set "Line=%%x") & call:doline  
pause
goto:eof
:doline
if "%line:~0,20%" equ "suchwort" (  
    set Write=True
    echo %line%>>"c:\bat\result.txt"  
) else (
    if not defined Write (
        echo %line%>>"c:\bat\andere.txt"      
    ) else (
        echo %line%>>"c:\bat\weitere.txt"  
        set Write=
    )
)
goto:eof

Grüße
bastla

P.S.: War kein Trick, sondern ein Flag (Schalter) ...

Flag ;)

Nein, leider keine Veränderung, gleiche Fehlermeldung wie vorher..

Hallo bufferm44!

Jetzt aber ...

@echo off & setlocal
set Write=
for /F "delims=" %%x in (c:\bat\test.txt) do set "Line=%%x" & call:doline  
goto :eof
:doline
if "%line:~0,20%" equ "suchwort" set Write=True & echo %line%>>"c:\bat\result.txt" & goto :eof  
if not defined Write echo %line%>>"c:\bat\andere.txt" & goto :eof  
echo %line%>>"c:\bat\weitere.txt"  
set Write=
goto :eof

Grüße
bastla

Moin!

Ich bin hochgradig begeistert, vielen Dank

Tobias

EDIT: Hm, kann ich das Thema nicht "als gelöst" deklarieren? Oder können das nur die Mods?

Hallo bufferm44!

... kann ich das Thema nicht "ald gelöst" deklarieren?

Kannst Du selbst, indem Du bei Deinem (Threaderöffnungs-)Beitrag auf "Editieren" gehst und dann ganz am Ende den entsprechenden Haken setzt.

Grüße
bastla

German closed solved Question Batch, Shell Development

Hotly discussed

End of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment