Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

Zelleninhalt per VBA in einer Spalte suchen

Frage Microsoft Microsoft Office

Mitglied: Schnufflchen

Schnufflchen (Level 1) - Jetzt verbinden

12.07.2009, aktualisiert 11:13 Uhr, 54026 Aufrufe, 23 Kommentare

Hallo,
meine VBA-Kenntnisse sind noch nicht so weit fortgeschritten, besitze aber Programmiererfahrung in Java, von daher klappts bisher eigentlich ganz gut.
Dennoch bin ich jetzt auf ein Problem gestoßen:
Ich habe in Tabellenblatt 1 eine Zelle, deren Inhalt in Tabellenblatt2 nur in Spalte A gesucht werden soll. Um zu prüfen, ob das funktioniert hab ich einfachheitshalber mal 2 msgboxen eingebaut, aber leider klappts mit der bedingung schon nicht.

ich wollte das ganze mit einer IF-Schleife machen, weil dann noch div. andere Aktionen folgen, wenn der Wert in Tabellenblatt 2 vorhanden ist.
Hier mal meine If-Schleife, vlt, kann mir jemand sagen, warum das nicht funktioniert

If Worksheets("Tabellenblatt1").Cells(2,6) = Worksheets("Tabellenblatt2").Range(Columns("A:A")) Then

MsgBox "Wurde gefunden"

Else
MsgBox "nicht vorhanden"


Dankeschön, schon mal vorab!
Mitglied: 76109
12.07.2009 um 12:13 Uhr
Hallo Schnufflchen!

Probiers mal damit:
01.
Private Sub Test() 
02.
  Dim Wks1 As Worksheet, Wks2 As Worksheet, Found As Object 
03.
     
04.
  Set Wks1 = Sheets("Tabelle1") 
05.
  Set Wks2 = Sheets("Tabelle2") 
06.
     
07.
  If Not IsEmpty(Wks1.Cells(2, 6)) Then 
08.
 
09.
     Set Found = Wks2.Columns(1).Find(Wks1.Cells(2, 6), LookIn:=xlValues, LookAt:=xlWhole) 
10.
     
11.
     If Found Is Nothing Then 
12.
          MsgBox "Wert nicht gefunden!", vbInformation, "Meldung" 
13.
     Else 
14.
          MsgBox "Wert in Zelle " & Found.Address, vbInformation, "Meldung" 
15.
     End If 
16.
   End If 
17.
End Sub
Gruß Dieter

[edit] If-Abfrage für Zelle = Leer hinzugefügt [/edit]
Bitte warten ..
Mitglied: Schnufflchen
12.07.2009 um 16:55 Uhr
Das ist super! Dankeschön. Eine Sache hab ich aber noch: Mir wird auch wenn der Wert nicht in der Spalte enthalten ist die Box ausgegeben, dasss der wert enthalten ist. wie bekomm ich das hin?
Bitte warten ..
Mitglied: 76109
12.07.2009 um 17:13 Uhr
Hallo Schnufflchen!

Ups, daran hatte ich nicht gedacht Code oben geändert.

Gruß Dieter
Bitte warten ..
Mitglied: Schnufflchen
12.07.2009 um 17:37 Uhr
Herzlichen Dank did1954,
du hast mir sooooo geholfen! Jetzt kann ich wieder weiterarbeiten!
Bitte warten ..
Mitglied: 76109
12.07.2009 um 17:52 Uhr
Hallo Schnufflchen!

Gern Geschehen

Falls Du auch Text suchst, in dem NICHT zwischen Groß/Kleinschreibung unterschieden werden soll,
dann füge am Blattanfang noch folgendes ein:
01.
Option Compare Text
Gruß Dieter
Bitte warten ..
Mitglied: s1rp4t
02.07.2010 um 18:15 Uhr
Moin moin,

Ich möchte den Inhalt von drei Zellen in der selben Zeile wie die gefundene Zelle kopieren, Ich habe mir gedacht, wenn ich die gefundene Zelle aktivieren kann, könnte ich das mit ActiveCell.Offset(0, 6).Range("A1").Select (wofür das A1 bei der Range?) aber ich bin ein VBA-Neuling und hab so noch keine wirkliche Idee, hier mein bisheriger Code, die Definitionen am Anfang sind Allgemeingültig und ich kopier sie aus Faulheit immer nur.




Dim WB As Workbook, WS1, WS2, WS3, WS4 As Worksheet
Dim i, LetzteZeileWS1, LetzteZeileWS2 As Long
Dim Dateiname2009, Dateiname2010, Suche As String
Dim Found As Object


Sub ABC()

Dateiname1 = "1.xls"
Dateiname2 = "2.xls"

Set WS1 = Workbooks(Dateiname1).Sheets("daten")
Set WS2 = Workbooks(Dateiname2).Sheets("daten")


LetzteZeileWS1 = WS1.Cells(Rows.Count, 1).End(xlUp).Row
LetzteZeileWS2 = WS2.Cells(Rows.Count, 1).End(xlUp).Row

For i = 1 To LetzteZeileWS2

If IsEmpty(WS2.Cells(i, 8)) Then

Set Found = WS1.Columns(2).Find(WS2.Cells(i, 2), LookIn:=xlValues, LookAt:=xlWhole)

If Found Is Nothing Then
' MsgBox "Wert nicht gefunden!", vbInformation, "Meldung"
Else
MsgBox "Wert in Zelle " & Found.Address, vbInformation, "Meldung"

End If
End If


Next


End Sub





Liebe Grüße
Bitte warten ..
Mitglied: 76109
02.07.2010 um 18:47 Uhr
Hallo s1rp4t!

In etwa so:
01.
If Found Is Nothing Then 
02.
    MsgBox "Wert nicht gefunden!", vbInformation, "Meldung" 
03.
Else 
04.
    'Beispiel: Kopiert die gefundene Zelle plus 3 weitere Zellen, also 4 Zellen nach A1-D1 
05.
    Range(Found, Found.Offset(0, 3)).Copy Destination:=Range("A1") 
06.
     
07.
    'Beispiel: Kopiert von der gefundenen Zelle die erste Zelle daneben plus 3 weitere Zellen, auch 4 Zellen nach A1-D1 
08.
    Range(Found.Offset(0, 1), Found.Offset(0, 4)).Copy Destination:=Range("A1") 
09.
End If
Wobei die Variable Set Found das Range-Object der gefundenen Zelle repräsentiert.

Gruß Dieter

PS. Wenn sich die zu kopierenden Zellen links von der gefundenen Zelle befinden, dann für den Spalten-Offset ein Minuszeichen voranstellen z.B. Offset(0, -4)
Bitte warten ..
Mitglied: s1rp4t
05.07.2010 um 08:54 Uhr
Vielen Dank für die schnelle Antwort, hab es leider erst jetzt lesen können.

Mein If-Tag sieht wie folgt aus, leider macht er mir immer Probleme mit dem copy und dem paste



If Found Is Nothing Then
MsgBox "Wert nicht gefunden!", vbInformation, "Meldung"
Else
'Beispiel: Kopiert die gefundene Zelle plus 3 weitere Zellen, also 4 Zellen nach A1-D1

Range(Found, Found.Offset(0, 3)).Copy Destination:=Range("A1")
Windows(Dateiname1).Activate
## ActiveSheet.Cells(i, 8).Select
ActiveSheet.Paste

Range(Found, Found.Offset(0, 3)).Copy Destination:=Range("A1")
ActiveSheet(i, 9).Select
ActiveSheet.Paste
Windows(Dateiname1).Activate

Range(Found, Found.Offset(0, 3)).Copy Destination:=Range("A1")
ActiveSheet(i, 10).Select
ActiveSheet.Paste
Windows(Dateiname1).Activate
'Beispiel: Kopiert von der gefundenen Zelle die erste Zelle daneben plus 3 weitere Zellen, auch 4 Zellen nach A1-D1
'Range(Found.Offset(0, 1), Found.Offset(0, 4)).Copy Destination:=Range("A1")

End If



Statt >>Activesheet(i, 10).Select<< hatte ich >>WS1.Cells(i, 10).Select<< probiert, das wollte er nicht, jetzt gibt er mir die Fehlermeldungen
"Die Paste-Methode des Worksheet-Objektes konnte nicht ausgeführt werden" bei ##
Bitte warten ..
Mitglied: 76109
05.07.2010 um 10:15 Uhr
Hallo s1rp4t!

Also, den Paste-Befehl brauchst Du nicht, weil z.B. diese Zeile
01.
Range(Found.Offset(0, 1), Found.Offset(0, 4)).Copy Destination:=Range("A1") 
den Kopier- und Einfügvorgang schon beinhaltet. D.h. Destination (Ziel) steht für die Einfüg-Zelle.

Dieses Code-Beispiel sollte Dich Deinem Ziel etwas näher bringen (Offsets bei Bedarf anpassen):
01.
Sub ABC() 
02.
    Dim WB As Workbook, WS1 As Worksheet, WS2 As Worksheet, Found As Object 
03.
    Dim i As Long, LetzteZeileWS1 As Long, LetzteZeileWS2 As Long 
04.
    Dim Dateiname1 As String, Dateiname2 As String, Suche As String 
05.
 
06.
    Dateiname1 = "1.xls" 
07.
    Dateiname2 = "2.xls" 
08.
     
09.
    Set WS1 = Workbooks(Dateiname1).Sheets("daten") 
10.
    Set WS2 = Workbooks(Dateiname2).Sheets("daten") 
11.
     
12.
    LetzteZeileWS1 = WS1.Cells(WS1.Rows.Count, 1).End(xlUp).Row 
13.
    LetzteZeileWS2 = WS2.Cells(WS2.Rows.Count, 1).End(xlUp).Row 
14.
     
15.
    For i = 1 To LetzteZeileWS2 
16.
     
17.
        If Not IsEmpty(WS2.Cells(i, 2)) And IsEmpty(WS2.Cells(i, 8)) Then 
18.
         
19.
            Set Found = WS1.Columns(2).Find(WS2.Cells(i, 2), LookIn:=xlValues, LookAt:=xlWhole) 
20.
             
21.
            If Found Is Nothing Then 
22.
                MsgBox "Wert nicht gefunden!", vbInformation, "Meldung" 
23.
            Else 
24.
                Range(Found.Offset(0, 6), Found.Offset(0, 8)).Copy Destination:=WS2.Cells(i, 8) 
25.
            End If 
26.
        End If 
27.
    Next 
28.
End Sub
In Makros benötigst Du keine Activate und Select-Anweisungen, da Du Tabellen über Namen und Zellen über Adressen explizit ansprechen kannst.

Gruß Dieter
Bitte warten ..
Mitglied: s1rp4t
05.07.2010 um 10:24 Uhr
Vielen Dank, ich werde das bis zum Mittag mal ausprobieren und mich bei Bedarf noch mal melden.

Liebe Grüße
Bitte warten ..
Mitglied: s1rp4t
05.07.2010 um 15:57 Uhr
So ich habe jetzt noch einen draufgesetzt (man muss sich ja steigern )

Das ist ein Code für eine andere Tabelle.
01.
For i = 2 To 1103 
02.
 
03.
    If Not IsEmpty(WS1.Cells(i, 1)) Then 
04.
            Set Found = WS2.Columns(1).Find(WS1.Cells(i, 1), LookIn:=xlValues, LookAt:=xlWhole) 
05.
            If Found Is Nothing Then 
06.
                'MsgBox "Wert nicht gefunden!", vbInformation, "Meldung" 
07.
            Else 
08.
##          Set Found2 = WS3.Columns(1).Find(WS2.Cells(Found.Offset(0, 1)), LookIn:=xlValues, LookAt:=xlWhole) 
09.
                Range(Found2.Offset(0, 5)) = 1 
10.
            End If 
11.
        End If 
12.
 
13.
    If Not IsEmpty(WS1.Cells(i, 2)) Then 
14.
            Set Found = WS2.Columns(1).Find(WS1.Cells(i, 2), LookIn:=xlValues, LookAt:=xlWhole) 
15.
            If Found Is Nothing Then 
16.
                'MsgBox "Wert nicht gefunden!", vbInformation, "Meldung" 
17.
            Else 
18.
            Set Found2 = WS3.Columns(1).Find(WS2.Cells(Found.Offset(0, 1)), LookIn:=xlValues, LookAt:=xlWhole) 
19.
                Range(Found2.Offset(0, 5)) = 2 
20.
            End If 
21.
        End If 
22.
         
23.
    If Not IsEmpty(WS1.Cells(i, 4)) Then 
24.
            Set Found = WS2.Columns(1).Find(WS3.Cells(i, 1), LookIn:=xlValues, LookAt:=xlWhole) 
25.
            Set Found2 = WS1.Columns(4).Find(WS2.Cells(Found.Offset(0, -1)), LookIn:=xlValues, LookAt:=xlWhole) 
26.
                 
27.
            If Found2 Is Nothing Then 
28.
             
29.
                WS3.Cells(i, 6) = 3 
30.
                 
31.
            Else 
32.
             
33.
            End If 
34.
        End If 
35.
 
36.
Next 
37.
 
Er gibt mir die Meldung "Anwendungs- oder Objektdefinierter Fehler." bei ## aus.

An WS3 oder Found liegt es nicht, ich wüsste aber nicht wieso Found2 Probleme machen sollte...

[Edit Biber] Codetax. Als ich jung war, konnte ich auch noch ohne lesen...[/Edit]
Bitte warten ..
Mitglied: s1rp4t
05.07.2010 um 16:09 Uhr
Vielleicht noch kurz der Hinweis wie ich meine Variablen definiert habe:



Dim sDatei As String, sPfad As String, i As Long
Dim WB As Workbook, WS1, WS2, WS3, WS4 As Worksheet
Dim LetzteZeileWS1, LetzteZeileWS2 As Long
Dim Dateiname1, Dateiname2, Suche As String
Dim Found, Found2 As Object


Liebe Grüße
Bitte warten ..
Mitglied: 76109
05.07.2010 um 21:22 Uhr
Hallo s1rp4t!

Die Variable Set Found beinhaltet schon die komplette Adresse Arbeitsmappe.Tabellenblatt.Range. Von daher nur die Variable Found angeben.
Also anstatt:
01.
Set Found2 = WS3.Columns(1).Find(WS2.Cells(Found.Offset(0, 1)), LookIn:=xlValues, LookAt:=xlWhole) 
so schreiben:
01.
Set Found2 = WS3.Columns(1).Find(Found.Offset(0, 1), LookIn:=xlValues, LookAt:=xlWhole) 
Das gleiche gilt auch für Zeile 18 und 25. Wobei Du das Found2-Ergebnis "If Found2 Is Nothing" (nicht gefunden) oder "If Not Found2 Is Nothing" (gefunden) von Zeile 18 nicht ausgewertet hast

Noch ein Hinweis zum deklarieren Deiner Variablen. Wenn Du z.B.
01.
Dim x, y, z As Long
schreibst, dann ist nur die Variable z als Long definiert. Die Variablen x und y dagegen als Variant. Also ohne Angabe vor dem nächsten Komma immer Variant und steht für alle Datentypen.

Gruß Dieter

[Edit] Und ich Schussel hätte ja darauf hinweisen können, den Code in Code-Tags zu setzen (siehe Formatierungshilfe), aber Biber hat's mal wieder gerichtet [/edit]
Bitte warten ..
Mitglied: s1rp4t
06.07.2010 um 08:47 Uhr
Nochmals Danke


01.
 
02.
For i = 2 To 1103 
03.
 
04.
    If Not IsEmpty(WS1.Cells(i, 1)) Then 
05.
            Set Found = WS2.Columns(1).Find(WS1.Cells(i, 1), LookIn:=xlValues, LookAt:=xlWhole) 
06.
            If Found Is Nothing Then 
07.
                'MsgBox "Wert nicht gefunden!", vbInformation, "Meldung" 
08.
            Else 
09.
           Set Found2 = WS3.Columns(1).Find(Found.Offset(0, 1), LookIn:=xlValues, LookAt:=xlWhole) 
10.
##              WS3.Cells(Found2.Offset(0, 5)) = 1 
11.
            End If 
12.
        End If 
13.
 
14.
    If Not IsEmpty(WS1.Cells(i, 2)) Then 
15.
            Set Found = WS2.Columns(1).Find(WS1.Cells(i, 2), LookIn:=xlValues, LookAt:=xlWhole) 
16.
            If Found Is Nothing Then 
17.
                'MsgBox "Wert nicht gefunden!", vbInformation, "Meldung" 
18.
            Else 
19.
            Set Found2 = WS3.Columns(1).Find(Found.Offset(0, 1), LookIn:=xlValues, LookAt:=xlWhole) 
20.
                Range(Found2.Offset(0, 5)) = 2 
21.
            End If 
22.
        End If 
23.
         
24.
    If Not IsEmpty(WS1.Cells(i, 4)) Then 
25.
            Set Found = WS2.Columns(1).Find(WS3.Cells(i, 1), LookIn:=xlValues, LookAt:=xlWhole) 
26.
            Set Found2 = WS3.Columns(1).Find(Found.Offset(0, 1), LookIn:=xlValues, LookAt:=xlWhole) 
27.
                 
28.
            If Found2 Is Nothing Then 
29.
             
30.
                WS3.Cells(i, 6) = 3 
31.
                 
32.
            Else 
33.
             
34.
            End If 
35.
        End If 
36.
 
37.
Next 
38.
 

Jetzt sagt er mir "Objektvariable oder With-Blockvariable nicht festgelegt" Ich hatte den Fehler schon mal, aber ich weiß nicht -.-" Ich bin echt am verzweifeln und muss den Code eigentlich bis um 9 fertig haben
Bitte warten ..
Mitglied: s1rp4t
06.07.2010 um 08:51 Uhr
Vielleicht noch kurz zur Erklärung, ich möchte, dass er in die Zelle eine "1" einfügt, die Fehlermeldung kam bei ##

Edit:
Ich hab das Range in WS3.Cells umbenannt, bei beidem kommt die gleiche Meldung...
Bitte warten ..
Mitglied: 76109
06.07.2010 um 09:14 Uhr
Hallo s1rp4t!

Für Zeile 10 und 20 gilt für das Found2-Range-Object das Gleiche

Die Set-Variable Found entspricht bereits einer Range-Objekt-Adresse und bedarf keiner Zuweisung mittels WS3.Cells... oder WS3.Range...

Den Namen der Arbeitsmappe und des Tabellenblattes hast Du ja per Set-Anweisung der Variablen WS3 zugewiesen und bei der Set-Anweisung mit dem Find-Befehl:
01.
Set Found2 = WS3.Columns(1).Find(Found.Offset(0, 1), LookIn:=xlValues, LookAt:=xlWhole)
wird der Variablen Found2 die komplette Adresse zugewiesen und heißt soviel wie: Set Found2 = WS3.Range(gefundene Zelle)

Also, z.B. nur "Found2.Offset(0, 5) = 2" schreiben.

Gruß Dieter
Bitte warten ..
Mitglied: s1rp4t
06.07.2010 um 09:21 Uhr
Vielen Dank, das Makro läuft bis zum 3. If-Tag, da meckert er wieder über das Problem vom Anfang, hier das If-Tag:
01.
    If Not IsEmpty(WS1.Cells(i, 4)) Then 
02.
##       Set Found = WS2.Columns(1).Find(WS3.Cells(i, 1), LookIn:=xlValues, LookAt:=xlWhole) 
03.
            Found2 = WS3.Columns(1).Find(Found.Offset(0, 1).Value, LookIn:=xlValues, LookAt:=xlWhole) 
04.
  
05.
            If Found2 Is Nothing Then 
06.
      
07.
                'WS3.Cells(i, 6) = 3 
08.
        
09.
            Else 
10.
          
11.
            End If 
12.
        End If
"Objektvariable oder With-Blockvariable nicht festgelegt"
Bitte warten ..
Mitglied: s1rp4t
06.07.2010 um 09:27 Uhr
Hab das 3. IF-Tag mal kommentiert und den Code ausgeführt, allerdings passiert da nichts, hab mir dann in "WS1.Cells(i, 3) = Found" Found ausgeben lassen, die Zellen bleiben leer, hast du eine Idee wieso?



Edit:
Jetzt gibt er mir Found aus, allerdings soll Found ja eine Zelle sein und kein Wert, wird Found nun die Zelle oder der Wert der Zelle zugewiesen? Weil Found2 hat keinen Wert und das kann ja eigtl nciht sein, oder?
Bitte warten ..
Mitglied: 76109
06.07.2010 um 09:29 Uhr
Hallo s1rp4t!

In Zeile 3 fehlt die Set-Anweisung: Set Found2

Meine letzte Antwort habe ich nochmal überarbeitet, also nochmal durchlesen.

Gruß Dieter

[edit]
Hab ich weiter oben doch schon geschrieben. Die Variable Found steht für ein Range-Object (Zell-Adresse).

Angenommen der Suchbegriff wurde in WS3 in Zelle A10 gefunden, dann steht Found für WS3.Range("A10") oder Found.Offset(0, 1) für WS3.Range("B10")
[/edit]
Bitte warten ..
Mitglied: s1rp4t
06.07.2010 um 09:35 Uhr
01.
 
02.
    If Not IsEmpty(WS1.Cells(i, 4)) Then 
03.
            Set Found = WS2.Columns(1).Find(WS3.Cells(i, 1), LookIn:=xlValues, LookAt:=xlWhole) 
04.
  ##     Set Found2 = WS3.Columns(1).Find(Found.Offset(0, 1), LookIn:=xlValues, LookAt:=xlWhole) 
05.
  
06.
            If Found2 Is Nothing Then 
07.
      
08.
                WS3.Cells(i, 6) = 3 
09.
        
10.
            Else 
11.
          
12.
            End If 
13.
        End If 
14.
 
15.
Next 
16.
 

Ich weiß nicht wieso, aber er hat das gleiche Problem... - Es würde aber auch ohne das 3. If-Tag gehen, wenn die anderen beiden funktionieren würden, denn ich könnte ja ausschließen. Hast du eine Idee wieso er für Found2 keinen Wert hat?

Liebe Grüße
Bitte warten ..
Mitglied: 76109
06.07.2010 um 09:44 Uhr
Hallo s1rp4t!

Vermutlich, weil Found Nothing ist?

Du musst natürlich erstmal ermitteln, ob die Variable Found was gefunden hat. Bedeutet:
01.
If Not Found Is Nothing Then  
02.
    Set Found2 = WS3.Columns(1).Find(Found.Offset(0, 1), LookIn:=xlValues, LookAt:=xlWhole)  
03.
 
04.
    If Found2 Is Nothing Then WS3.Cells(i, 6) = 3 
05.
End If  
Gruß Dieter
Bitte warten ..
Mitglied: s1rp4t
06.07.2010 um 10:05 Uhr
Tausend Dank, es hat alles geklappt =)
Bitte warten ..
Mitglied: 76109
06.07.2010 um 10:31 Uhr
Hallo s1rp4t!

Gern geschehen, freut mich, wenn's nun funktioniert

Gruß Dieter
Bitte warten ..
Neuester Wissensbeitrag
Humor (lol)

Linkliste für Adventskalender

(3)

Information von nikoatit zum Thema Humor (lol) ...

Ähnliche Inhalte
Microsoft Office
gelöst Verschieben von Zellinformation in andere Spalte (per VBA) excel 2010 (5)

Frage von thomas1972 zum Thema Microsoft Office ...

VB for Applications
gelöst Mit VBA im Monatskalender Datum suchen - aus anderer Datei einfügen (6)

Frage von Otto1699 zum Thema VB for Applications ...

VB for Applications
gelöst Excel VBA .csv Import in Tabelle x, ab Spalte y

Frage von drimrim zum Thema VB for Applications ...

Heiß diskutierte Inhalte
Router & Routing
gelöst Ipv4 mieten (22)

Frage von homermg zum Thema Router & Routing ...

Exchange Server
gelöst Exchange 2010 Berechtigungen wiederherstellen (20)

Frage von semperf1delis zum Thema Exchange Server ...

Windows Server
DHCP Server switchen (20)

Frage von M.Marz zum Thema Windows Server ...

Hardware
gelöst Negative Erfahrungen LAN-Karten (19)

Frage von MegaGiga zum Thema Hardware ...