HowTo - Firefox-Einstellungen automatisch sichern und wiederherstellen

@echo off
REM ======================================================================
REM NAME: FFProfileBackup
REM AUTHOR: Arne Richter
REM DATE  : 16.Mai 2005
REM MAIL  : binaryzero(at)decayed.de
REM COMMENT: Backup or restore Firefox Profile Folder
REM ======================================================================
cls
color 4c
title Firefox Profile Backup und Restore
set err=
set mozprof=
set moztemp=
set param1=%1
set param2=%2


:MAIN
call :SUB_CINFO
call :FF_CHECK
call :SUB_CINFO
call :SUB_CHECK
goto :END

REM *************************************************************
:SUB_CINFO
REM *************************************************************
cls
@echo **********************************************************
@echo Firefox Profile Backup und Restore
@echo Arne Richter binaryzero(at)decayed.de 16.05.2005
@echo free copying allowed, but if so 
@echo keep my copyright informations in the file
@echo **********************************************************
@echo.
@echo.
goto :EOF

REM *************************************************************
:FF_CHECK
REM *************************************************************
call :SUB_CINFO
ver | find /i "5.1" >nul: && (set xp=1) || (set xp=0)  
echo hier
if "%xp%" equ "1" (  
		tasklist | find /i "firefox.exe" >nul 2>&1 && (  
		@echo Bitte beenden Sie Firefox nun, sonst kann nicht kopiert werden!
		@echo Wenn Sie fertig sind, dann..
		pause
		goto :FF_CHECK
		)
		)
if "%xp%" equ "0" (  
		@echo Bitte beenden Sie Firefox nun, sonst kann nicht kopiert werden!
		@echo Wenn Sie fertig sind, dann..
		pause
		)
call :SUB_CINFO
goto :EOF

REM *************************************************************
:SUB_CHECK
REM *************************************************************
@if not "%ECHO%"=="" echo %ECHO%  
@if not "%OS%"=="Windows_NT" (set err=48 & goto :err)  
if "%param1%" equ "" goto :syntax  
@echo Parameter1: %param1%
@echo Parameter2: %param2%
set mozprof="%userprofile%\anwendungsdaten\mozilla\firefox"  
set moztemp="%temp%\firefox"  
if "%param2%" neq "" (  
	if not exist "%param2%" (  
		md "%param2%" & set moztemp=%param2%  
	)
)

if "%param1%"=="" set err=51 & goto :error  
if "%param1%"=="backup" goto :backup  
if "%param1%"=="restore" goto :restore  
set err=51 & goto :error
goto :EOF

REM *************************************************************
:backup
REM *************************************************************
cls
call :SUB_CINFO
set /p ask=Wollen Sie die aktuellen Einstellungen fuer Firefox sichern [J/N]?
if /i "%ask%" equ "n" set err=52 & goto :error  
if /i "%ask%" neq "j" set err=53 & goto :error  
call :SUB_CINFO
if exist %moztemp% (
	@echo altes Sicherungsverzeichnis existiert im Pfad %moztemp%
	@echo Verzeichnis %moztemp% wird geloescht
	rmdir  /q /s %moztemp%
	)
@echo Sicherungsverzeichnis wird in %moztemp% angelegt
md %moztemp%
@echo Profil wird gesichert
@echo von %mozprof% 
@echo nach %moztemp%
xcopy %mozprof% %moztemp% /e /y >nul 2>&1
call :SUB_CINFO
@echo Firefox-Profile wurde nach %moztemp% gesichert
goto :EOF

REM *************************************************************
:restore
REM *************************************************************
call :SUB_CINFO
set /p ask=Wollen Sie die aktuellen Einstellungen fuer Firefox ueberschreiben [J/N]?
if /i "%ask%" equ "n" set err=52 & goto :error  
if /i "%ask%" neq "j" set err=53 & goto :error  
call :SUB_CINFO
@echo Sicherungsverzeichnis %moztemp%
@echo Profileordner %mozprof% wird geloescht
rmdir /q /s %mozprof%
@echo Profileordner %mozprof% wird neu angelegt
md %mozprof%
@echo Sicherung von %moztemp% wird in %mozprof% wiederhergestellt
xcopy %moztemp% %mozprof% /e /y >nul 2>&1
@echo Firefox-Profile wurde in %mozprof% wiederhergestellt
goto :EOF

REM *************************************************************
:error
REM *************************************************************
call :SUB_CINFO
	if %err%==49 @echo der angegebene Backup-Pfad existiert nicht!
	if %err%==50 @echo Firefox laeuft noch, bitte beenden!
	if %err%==51 (
		@echo es wurde ein falscher Parameter angegeben!
		goto :syntax
		)
	if %err%==52 @echo der Vorgang wurde vom Benutzer abgebrochen.
	if %err%==53 @echo Es sind nur j / J / n / N als Antwort erlaubt, Abbruch.
@echo **********************************************************
goto :END

REM *************************************************************
:syntax
REM *************************************************************
	@echo Syntax: 
	@echo "FFProfileBackup.cmd backup [Backup-Pfad]" zum Sichern  
	@echo "FFProfileBackup.cmd restore [Backup-Pfad]" zum Wiederherstellen  
goto :EOF

REM *************************************************************
:END
REM *************************************************************
@echo.
pause
call :SUB_CINFO
@echo ..fertig!
echo.