Robocopy Backup Script

@echo off
rem Author: Martin Weber
rem ######################################### Anfang Konfiguration
set quelle=
set ziel=
set anzahlBackups=5
rem ######################################### Ende Konfiguration

if exist "%ziel%\BackUp\%date%" exit  
title BackUp starten ?
echo Drucken Sie eine beliebige Taste um das Backup zu starten...
pause > NUL
if not exist "%quelle%" (  
msg %username% "ERROR: Quelle exsistiert nicht"  
exit
)
if not exist "%ziel%" (  
msg %username% "ERROR: Ziel exsistiert nicht"  
exit
)
if not exist "%ziel%\BackUp" md "%ziel%\BackUp"  
for /F "tokens=2 delims=." %%i in ("%date%") DO (set month=%%i)  
for /F "tokens=3 delims=." %%i in ("%date%") DO (set jear=%%i)  
title BackUp ist gestartet
if not exist "%ziel%\BackUp\*.%month%.%jear%" (  
echo Erstelle vollstandiges Backup fur diesen Monat
robocopy "%quelle%" "%ziel%\BackUp\%date%" /MIR /tee /log:"%ziel%\BackUp.log"  
) else (
echo Aktualisiere das Backup von diesem Monat
move "%ziel%\BackUp\*.%month%.%jear%" "%ziel%\BackUp\%date%" > NUL  
if not exist "%ziel%\BackUp.log" echo %date% > "%ziel%\BackUp.log"  
robocopy "%quelle%" "%ziel%\BackUp\%date%" /MIR /tee /log+:"%ziel%\BackUp.log"  
)
echo Losche alte BackUps
for /f "skip=%anzahlBackups% delims=" %%F in ('dir /B /O-D /A:D %ziel%\BackUp') do rd /s /q "%ziel%\BackUp\%%F"  
msg %username% "Das BackUP wurde erfolgreich durchgefuhrt"