Batch zum zusammenfügen von CSV Dateien und dem hinzufügen des Dateinamens

Hallo liebes Forum,

ich habe gesehen, dass hier einige sehr engagierte und fachkundige User unterwegs sind und ich würde mich freuen, wenn man mir bei meinem Problem helfen könnte.

Ich habe in einem Ordner ziemlich viele csv Dateien und ich möchte diese gesammelt in einer Datei speichern. Das habe ich noch hinbekommen!

Die csv Datei sieht folgender Maßen aus (eine Zeile als Beispiel):

Transaction ID,"Transaction Code","User","Domain","Location","Datum und Uhrzeit","Datum und Uhrzeit","Länge","Rate","Preis","Acces Type","Usage"

Mein Batch, dass diese Dateien zusammenfügt, sieht folgender Maßen aus:


for /f "delims=" %%a in ('dir /a-d /b *.csv^|findstr /vic:"gesammelt.cs"') do >>"gesammelt.csv" type "%%~a"


Am Ende entsteht die Datei gesammelt.csv mit allen Zeilen der jeweiligen Dateien. Nun hätte ich aber gerne den Dateinamen der Datei als extra Spalte!

Der Dateiname sieht wie folgt aus:

sess=02cfffc6d6b2868ce833b2dc4c821e85&m=Datum&f=Datei.html&z=1056446&c=1045675.csv

Nun hätte ich gerne in meiner zusammen gefassten Datei die letzten Ziffern (in diesem Fall 1045675) des Dateinamens als Spalte um diese als Indikator zu nutzen zum wem ich das zuordnen muss.

Wäre super, wenn jemand hier eine Lösung parat hätte, mir würde es eine Menge Arbeit ersparen


Danke im Voraus für die Hilfe!

Grüße

@echo off & setlocal
set "Sammel=gesammelt.csv"  
set "Delim=,"  

>"%Sammel%" type nul  
for /f "delims=" %%a in ('dir /a-d /b *.csv^|findstr /vic:"%Sammel%"') do call :ProcessFile "%%a"  
goto :eof

:ProcessFile
for /f "tokens=6 delims==" %%i in ("%~n1") do set "Datei=%%i"  
(for /f "usebackq eol=§ delims=" %%i in (%1) do (  
    set "Zeile=%%i"  
    setlocal enabledelayedexpansion
    echo !Zeile!%Delim%%Datei%
    endlocal
))>>"%Sammel%"  
goto :eof

setlocal enabledelayedexpansion
>"gesammelt.csv" type nul  
for /f "delims=" %%a in ('dir /a-d /b *.csv^|findstr /vic:"gesammelt.cs"') do call :process "%%a"  
goto :eof

:Process
for /f "tokens=6 delims==" %%x in ("%~1") do set number=%%~nx  
for /f "delims=" %%z in ('type "%~1"') do set "zeile=%%z" & @echo %number%,!zeile! >> gesammelt.csv   
goto :eof

setlocal enabledelayedexpansion
>"gesammelt.csv" type nul  
for /f "delims=" %%a in ('dir /a-d /b *.csv^|findstr /vic:"gesammelt.cs"') do (  
    for /f "tokens=6 delims==" %%x in ("%%~na") do set number=%%~nx  
    for /f "delims=" %%z in ('type "%%a"') do set "zeile=%%z" & @echo !number!,!zeile!  
)>>gesammelt.csv