wisch
Apr 29, 2009, updated at 06:52:10 (UTC)
view5415
view5
0
Goto Top

TXT-Dateien splitten in Zeile 1 und Zeile 2-x

GermansolvedQuestionBatch, ShellDevelopment
Hallo.
Ich möchte alle TXT Datei eines Verzeichnisses splitten und in zwei neue Dateien ausgeben.
Dabei soll die 1. Zeile der Quelldateien in der 'artikel.txt' landen und alle weiteren Zeilen der
Quelldateien in 'stueckliste.txt' ....

Hier mein nicht funktionierender Versuch:

@echo off 
cls

set pfad=C:\empfang
set datei=IMP_*.txt
set /a zeile=0

:start
for %%d in ("%pfad%\%datei%") do call :separieren "%%d"
goto :ende

:separieren
for /f "delims=" %%a in (%1) do (
 set /a zeile=%zeile%+1
 if %zeile% EQU 1 echo %%a>>artikel.txt
 if %zeile% GTR 1 echo %%a>>stueckliste.txt
)

:ende
pause

Als Ergebnis erhalte ich immer nur die Datei artikel.txt mit dem Inhalt der gerfundenen Dateien inkl. Pfad.

Was tun?

Danke.
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 114925

Url: https://administrator.de/contentid/114925

Printed on: April 26, 2024 at 15:04 o'clock

5 Comments
Latest comment
Goto Top
Mitglied: 77559
77559 Apr 29, 2009 at 07:23:05 (UTC)
Goto Top
Variablen in eingeklammerten Bereichen werden durch den CMD interpreter nur einmal zu Beginn aufgelöst.
Das heisst "if %zeile%" wertet nicht den aktuell gezählten Wert aus. Man kann dies aber erzwingen in dem am Anfang der Batch
setlocal EnambleDelayedExpansion
gesetzt wird und dann die Prozent- durch Ausrufezeichen ersetzt werden.
if !Zeile! ...

Ich würde aber einen anderen IMO effizienteren Weg vorschlagen. Mit
set /P ErsteZeile=<Datei
kann man eine Zeile in eine Variable einlesen, mit
more +x Datei
kann man x Zeilen überspringen.

@echo off
cls
set pfad=C:\empfang
set datei=IMP_*.txt
for %%d in ("%pfad%\%datei%") do call :separieren "%%~fd"  
goto :eof

:separieren
set /P ErsteZeile=<%1
echo/%ErsteZeile%1>>artikel.txt
more +1 %1 >>stueckliste.txt

Gruß
LotPings
Member: WiSch
WiSch Apr 29, 2009 at 07:50:19 (UTC)
Goto Top
Hallo LotPins.

Dank für die Antwort... funktioniert bei mir aber (noch) nicht...

Ich bekomme einen Syntaxfehler für die Zeile "set /P ErsteZeile=<%1" angezeigt...
In der Dosbox kommt dazu "set /P ErsteZeile= 0<"C:\empfang\IMP_Test Datei.txt"

Kann es an einem Leerzeichen im Dateinamen liegen?

Zusätzlich folgt noch eine Zeile "echo testtext|mehr Text|auch mit Sonderzeichen?|usw>>artikel.txt".
Eine artikel.txt wird aber nicht erstellt? Probleme mit Sonderzeichen?

Nach dieser letzten Zeile bricht er Kommentarlos ab!? ;(

Zusätzliche Frage/Bitte: Kannst Du mir genauer erklären, was da so im Script passiert? Bin da eher ein Script-Kiddie und verstehe z.B. nicht, warum beim Aufruf der Subroutine die Variable "%%~fd" statt "%%d" übergeben wird, oder warum ein Slash bei "echo/ %ErsteZeile%1>>artikel.txt" dabei steht...

DANKE!
Mitglied: 77559
77559 Apr 29, 2009 at 08:45:00 (UTC)
Goto Top
Zitat von @WiSch:
Hallo LotPins.
LotPings bitte, auf dem g bestehe ich face-wink

Ich bekomme einen Syntaxfehler für die Zeile "set /P ErsteZeile=<%1" angezeigt...
In der Dosbox kommt dazu "set /P ErsteZeile= 0<"C:\empfang\IMP_Test Datei.txt"

Kann es an einem Leerzeichen im Dateinamen liegen?
Eigentlich nicht, es wird ja gelesen. Sonst würde das Echo ja nichts ausgeben können.

Der Syntax Fehler bezieht sich mMn auf das echo.


Zusätzlich folgt noch eine Zeile "echo testtext|mehr Text|auch mit Sonderzeichen?|usw>>artikel.txt".
Eine artikel.txt wird aber nicht erstellt? Probleme mit Sonderzeichen?
Die haben ja auch eine spezielle Bedeutung: Ein-/Ausgabeumleitung,Pipe,Befehlverknüpfung.
Die müssen "Escaped" werden.

Nach dieser letzten Zeile bricht er Kommentarlos ab!? ;(

Zusätzliche Frage/Bitte: Kannst Du mir genauer erklären, was da so im Script passiert?
Bin da eher ein Script-Kiddie und verstehe z.B. nicht, warum beim Aufruf der Subroutine die Variable
"%%~fd" statt "%%d" übergeben wird,
Das stellt nur sicher das der Dateiname mit kompletten Angaben (fullname) weitergegeben wird

oder warum ein Slash bei "echo/ %ErsteZeile%1>>artikel.txt" dabei steht...
Für den Fall das die Variable ErsteZeile leer ist, verhindert es, das in Artikel.txt die Ausgabe Echo ist ON erscheint.

Diese Version sollte funktionieren
::Split1Line.cmd:::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off&setlocal
cls
set "pfad=F:\Test"  
set "datei=IMP_*.txt"  
for %%d in ("%pfad%\%datei%") do call :separieren "%%~fd"  
goto :eof
:separieren
echo Bearbeite %1
set /P ErsteZeile=<%1
set "ErsteZeile=%ErsteZeile:"=¼%"  
set "ErsteZeile=%ErsteZeile:^=^^%"  
set "ErsteZeile=%ErsteZeile:&=^&%"  
set "ErsteZeile=%ErsteZeile:<=^<%"  
set "ErsteZeile=%ErsteZeile:>=^>%"  
set "ErsteZeile=%ErsteZeile:|=^|%"  
set "ErsteZeile=%ErsteZeile:¼="%"  
echo/%ErsteZeile%1>>artikel.txt
more +1 %1 >>stueckliste.txt

Gruß
LotPings
Member: WiSch
WiSch Apr 29, 2009 at 08:56:36 (UTC)
Goto Top
Zitat von @77559:
LotPings bitte, auf dem g bestehe ich face-wink
Sorry... waren mal wieder "dicke Finger"! face-smile
Und "Rettet dem Dativ" gefällt mir! face-big-smile

Zum Thema:
Das Script läuft top! Schick gesplittet und inkl. aller Leer-, Sonder- und sonstwas-Zeichen!

DANKE!

Also gelöst, trotzdem noch die Frage, was die zusätzlichen "set"-Einträge bewirken...
Mitglied: 77559
77559 Apr 29, 2009 at 09:21:28 (UTC)
Goto Top
Zitat von @WiSch:

Also gelöst, trotzdem noch die Frage, was die zusätzlichen "set"-Einträge bewirken...
Ich schrieb doch schon, die Sonderzeichen
Die müssen "Escaped" werden.
Das heißt damit die Cmd Shell die Zeichen nicht in ihrer Sonderfunktion beachtet und ausführt,
müssen Sie alle maskiert werden mit dem ^Caret.
Die set Befehle ersetzen also jedes mögliche Sonderzeichen mit einer maskierten Version desselben.
| wird ^| , < wird ^< etc. so das das Echo problemlos ausgeführt werden kann.

Gruß
LotPings
GermansolvedQuestionBatch, ShellDevelopment