Windows Batch

Hallo

Ich habe eine umfangreiche CSV-Datei, bei der ich einige Spalten auslesen will und diese in eine neue CSV-Datei schreiben möchten.

Jetzt habe ich das Problem, dass bei meinem Output nur die letzte Zeile der test.csv Datei erscheint.

Mein Skript sieht wie folgt aus.

For /F "tokens=4,5,6,10,11,13,14,15 delims=;" %%i in (test.csv) do (
set DeviceIdentifier=%%l.domain.xy
set Port=1
set Number=%%l
set NameTemp=%%j %%k, %%n %%i
set Name=%NameTemp:~0,32%
set DeviceLocation=%%p
set SystemLocation=%%o
set SystemContact=%%m
echo %DeviceIdentifier%,%Port%,%Number%,%Name%,%DeviceLocation%,%SystemLocation%,%SystemContact%>>output.csv
)

In der CMD-Box sehe ich aber wie die definierten Variablen mit den richtigen Werten erscheinen.

Kann mir da jemand weiter helfen?

Vielen Dank und Gruss

Santamaria

For /F "tokens=4,5,6,10,11,13,14,15 delims=;" %%i in (test.csv) do (  
  set "DeviceIdentifier=%%l.domain.xy"  
  set "Number=%%l"  
  set "NameTemp=%%j %%k, %%n %%i"  
  set "DeviceLocation=%%p"  
  set "SystemLocation=%%o"  
  set "SystemContact=%%m"  
  setlocal EnableDelayedExpansion
  echo !DeviceIdentifier!,1,!Number!,!NameTemp:~0,32!,!DeviceLocation!,!SystemLocation!,!SystemContact!>>output.csv
  endlocal
)