Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

Mit Batch in n Zeile schreiben

Frage Entwicklung Batch & Shell

Mitglied: Klette84

Klette84 (Level 1) - Jetzt verbinden

10.11.2012 um 00:27 Uhr, 2742 Aufrufe, 17 Kommentare

Hallo,

ich möchte gern in eine Bestimte Zeile in einer *.txt Datei schreiben. Könnt ihr mir weiter helfen?

Ich bin so weit gekommen das er mir die bestimmten Zeilen in den geschrieben werden sollen aus giebt.

FOR /F "delims=:" %%A IN ('findstr /N .* "1000.txt"') DO set Zeilen=%%A

echo es sind %Zeilen% Zeilen

set /a zehn=%Zeilen%/10
echo 10%% = %zehn%

set /a zwanzig=%zehn%*2
echo 20%% = %zwanzig%

set /a dreissig=%zehn%*3
echo 30%% = %dreissig%

set /a vierzig=%zehn%*4
echo 40%% = %vierzig%

set /a fuenfzig=%Zeilen%/2
echo 50%% = %fuenfzig%

set /a sechzig=%zehn%*6
echo 60%% = %sechzig%

set /a achzig=%zehn%*8
echo 80%% = %achzig%

set /a neunzig=%zehn%*9
echo 90%% = %neunzig%

echo 100%% = %Zeilen%


pause
goto :eof

Wie bekomme ich es hin das er mir die zB. 40% in die n-Zeile schreibt?
Mitglied: bastla
10.11.2012, aktualisiert um 09:54 Uhr
Hallo Klettte64!

Unabhängig davon, was Du eigentlich vorhast (denn davon wissen wir ja nix, wie auch nicht über den Inhalt der bereits vorhandenen Zeilen in der Textdatei) könntest Du mit dem folgenden Batch den Inhalt einer Variablen %Zeile% in die in der Variablen %ZeilenNr% festgelegte Zeile der bestehenden Textdatei "1000.txt" schreiben und deren übrige Zeilen unverändert (außer, diese würden mit ":" beginnen) übernehmen:
01.
@echo off & setlocal 
02.
set "Ordner=D:\Dein Ordner" 
03.
set "Datei=1000.txt" 
04.
set /a ZeilenNr=15 
05.
set "ZeileNeu=Neue Zeile" 
06.
 
07.
move "%Ordner%\%Datei%" "%temp%\%Datei%" 
08.
(for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%temp%\%Datei%"') do ( 
09.
    if %%i neq %ZeilenNr% (echo(%%j) else (echo %ZeileNeu%) 
10.
))>"%Ordner%\%Datei%"
Grüße
bastla
Bitte warten ..
Mitglied: Klette84
10.11.2012 um 14:07 Uhr
Danke für die schnelle Antwort leider ersetzt er mir die n-Zeile und fügt keine neue ein...

Das ganze wird für ein Schlichtprogramm an der CNC-Maschine benötigt. Da diese Programme per CAD/CAM erstellt werden und zum teil Stunden dauern bis sie abgearbeitet sind.

Da her die Idee per Batch die Datei einlesen, herausfinden wie viele Zeilen es sind und bei der n-Zeile von 10% 20% 30% usw. eine neue Zeile einfügen mit MSG("Programm bei x %"). So bekomme ich am Monitor eine Anzeige und kann ca sagen wann der Programmablauf fertig ist.

Ich wollte es erst mal einfach an einer *.txt Datei testen. Später werden es *.mpf Datein sein...
Bitte warten ..
Mitglied: bastla
10.11.2012, aktualisiert um 15:58 Uhr
Hallo Klette84!

Naja, "in Zeile n schreiben" ist für mich etwas anderes als "in Zeile n eine Zeile einfügen" - das würde ich für Deine (jetzt klare) konkrete Situation eher so machen:
01.
@echo off & setlocal 
02.
set "Ordner=D:\Dein Ordner" 
03.
set "Datei=1000.txt" 
04.
 
05.
move "%Ordner%\%Datei%" "%temp%\%Datei%" 
06.
for /f %%i in ('find /c /v "$$$$"^<"%temp%\%Datei%"') do set /a ZeilenGesamt=%%i 
07.
set /a Zehntel=ZeilenGesamt/10 
08.
set /a Stufe=1 
09.
set /a Z=Zehntel 
10.
for /f "delims=" %%i in ('findstr /n "^" "%temp%\%Datei%"') do set "Zeile=%%i" & call :ProcessLine 
11.
goto :eof 
12.
 
13.
:ProcessLine 
14.
setlocal enabledelayedexpansion 
15.
>>"%Ordner%\%Datei%" echo(!Zeile:*:=! 
16.
endlocal 
17.
set /a Z-=1 
18.
if %Z%==0 ( 
19.
    if %Stufe% lss 10 >>"%Ordner%\%Datei%" echo echo Programm bei %Stufe%0 %% 
20.
    set /a Z=Zehntel 
21.
    set /a Stufe+=1 
22.
23.
goto :eof
Die Schreibweise der Zeilen 14 bis 16 ist nur eine Vorsichtsmaßnahme, um die Originalzeilen exakt gleich (trotz ev Sonderzeichen, ":" am Anfang) in die (neue) Datei schreiben zu können.

Wenn die Zerlegung anhand des ":" problemlos funktioniert, kann das noch vereinfacht werden auf zB (ungetestet)
01.
@echo off & setlocal 
02.
set "Ordner=D:\Dein Ordner" 
03.
set "Datei=1000.txt" 
04.
 
05.
move "%Ordner%\%Datei%" "%temp%\%Datei%" 
06.
for /f %%i in ('find /c /v "$$$$"^<"%temp%\%Datei%"') do set /a ZeilenGesamt=%%i 
07.
set /a Zehntel=ZeilenGesamt/10 
08.
set /a Stufe=1 
09.
for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%temp%\%Datei%"') do call :ProcessLine %%i "%%j" 
10.
goto :eof 
11.
 
12.
:ProcessLine 
13.
>>"%Ordner%\%Datei%" echo(%2 
14.
set /a Mod=%1 %% Zehntel 
15.
if %Mod%==0 ( 
16.
    if %Stufe% lss 10 >>"%Ordner%\%Datei%" echo echo %Stufe%0 %% 
17.
    set /a Stufe+=1 
18.
19.
goto :eof
Grüße
bastla
Bitte warten ..
Mitglied: Klette84
10.11.2012 um 17:14 Uhr
Wahnsinn Danke! in Zeile 19 bzw 16 ist ein echo zu viel aber ansonsten alles bestens! Bin gespannt was bei der CNC-Maschine raus kommt.

ich würde mir das Skripten gerne noch etwas besser selber bei bringen. Kannst du mir ein gutes Buch empfehlen. Da mir die CMD mit /? nicht wirklich weiter hilft...

Bzw würde es den Rahmen sprengen wenn du mir jede Zeile einzeln erleuterst was welcher Befehl genau bewirt.
Bitte warten ..
Mitglied: bastla
10.11.2012 um 19:27 Uhr
Hallo Klette84!
in Zeile 19 bzw 16 ist ein echo zu viel
Ich war davon ausgegangen, dass die Zeile in der Datei etwa
echo Programm bei 40 %
lauten soll - und dann braucht es beide "echo" ...
Zum Ablauf (der Version 1):
  • Die ersten Zeilen dürften selbsterklärend sein ...

  • In Zeile 5 wird die Datei in den %temp%-Ordner verschoben, damit sie am Original-Speicherort wieder erstellt werden kann.
  • Zeile 6 ermittelt die Gesamtzeilenanzahl (etwas schneller) mit einer alternativen Methode (hier kannst Du auch Deine ursprüngliche Variante verwenden) - da alle Zeilen gezählt werden sollen, wird ein Begriff, den es in der Datei nicht gibt, als "negatives" Suchkriterium (= finde alle Zeilen außer jenen, die diesen Suchbegriff enthalten) verwendet; als Ergebnis liefert "find" dann nur die Zeilenanzahl (womit das Durchlaufen aller Zeilen in der Schleife eingespart wird).
  • Zeile 7 ist klar (wobei anzumerken ist, dass das Ergebnis einer Division in Batch immer eine abgerundete ganze Zahl ist).
  • In Zeile 8 wird der Zähler für die Zehn-Prozent-Stufen vorbelegt und in Zeile 9 die Zeilenanzahl, die einem Zehntel der Datei entspricht (nach der also dann jeweils die Ausgabe erfolgen soll).
  • Die Schleife in Zeile 10 liest alle Zeilen der Datei aus (indem als Suchbegriff der "Zeilenanfang" - den hat tatsächlich jede Zeile - verwendet wird), packt die Zeile in eine Variable und ruft für jede Zeile das Unterprogramm ":ProcessLine" auf. Der "findstr"-Schalter "/n}" wird übrigens hier nicht für die Zeilennummer benötigt, sondern verhindert, dass Leerzeilen einfach übersprungen würden.
  • Das Hauptprogramm endet in Zeile 11 (ansonsten würde das Unterprogramm am Ende nochmals durchlaufen).

  • Im Unterprogramm wird zunächst der Teil der Zeile nach dem ersten ":" ausgegeben - dazu wird alles bis zum ersten ":" durch "Nichts" ersetzt (siehe dazu "set /?)". Die Einbettung in einen "delayedExpansion"-Bereich beugt dabei Problemen mit ev enthaltenen Sonderzeichen vor. Die Schreibweise "echo(" entspricht dem bekannteren "echo." (funktioniert aber lt jeb-the-batcher auch in bestimmten Situationen, in denen es mit "." oder "\" nicht ginge, weswegen ich dazu übergegangen bin, sie grundsätzlich zu verwenden) und sorgt dafür, dass eine Leerzeile auch "leer" (und nicht als "ECHO ist ausgeschaltet (OFF)." ausgegeben wird.
  • Zeile 17 reduziert den Wert des Zeilenzählers um 1, und in Zeile 18 wird festgestellt, ob es Zeit für die Ausgabe der Information ist. Da durch die Abrundung (s. o.) die 100 % meist bereits vor der letzten Zeile erreicht werden, wird die Prozentstufe nur bist 90 % ausgegeben.
  • Wenn die Ausgabe vorzunehmen war, wird der Zeilenzähler wieder auf ein Zehntel der Zeilen gesetzt und die Zehner-Prozentstufe um 1 erhöht.
  • Die Zeile 23 wäre, da sie die letzte Zeile im Batch ist, nicht nötig - es schadet aber nicht, das Unterprogramm damit abzuschließen (um ggf dahinter noch weitere Zeilen, etwa für ein zweites Unterprogramm, hinzufügen zu können).

Grüße
bastla
Bitte warten ..
Mitglied: Klette84
14.11.2012 um 07:57 Uhr
Danke für dein ausführlichen Bericht. Ich hab aber schon wieder den nächsten hänger...

und zwar möchte ich das die *.bat im selbigen Ordner alle *.mpf Datein durch geht und den Fortschritt in die Datein schreibt.


echo.
echo.
set "Ordner=%~dp0"
for /f "delims=" %%i in ("%Ordner%*.mpf") do (set Datei=%%~nxi & call :Label)
goto :eof

:Label
move "%Ordner%%Datei%" "%temp%\%Datei%"
usw...

Das klapt mit der ersten Datei die er findet recht gut jedoch bricht er die for /f %%i ab! Was mache ich falsch?
Bitte warten ..
Mitglied: bastla
14.11.2012 um 08:13 Uhr
Hallo Klatte84!

Du hast eine Mischung von "for" und "for /f" fabriziert - letzteres liest entweder den Inhalt einer Datei zeilenweise aus oder verarbeitet das Ergebnis eines Befehls (hier wäre "dir /b" gefragt) - daher eher:
for /f "delims=" %%i in ('dir /b "%Ordner%*.mpf"') do (set "Datei=%%i" & call :Label)
Grüße
bastla
Bitte warten ..
Mitglied: Klette84
14.11.2012 um 12:40 Uhr
Super bastla!

leider giebt es immer noch ein kleinen Schöhnheitsfehler. Da die letzte Datei im Ordner 2 mal "gepatcht" wird. Also er schreibt 2 mal Programm bei X % in je 2 Zeilen.

Grüße Klette
Bitte warten ..
Mitglied: Klette84
14.11.2012 um 14:12 Uhr
wenn man neben bei arbeitet, übersieht man was schnell... Natürlich fehlte das goto :eof !

Also HIER die fertige Batch:


@echo off & setlocal

echo.
set "Ordner=%~dp0"
for /f "delims=" %%i in ('dir /b "%Ordner%*.mpf"') do (set "Datei=%%i" & call :Label)
goto :eof

:Label
echo.
echo Bitte warten, Programm %Datei% wird aktualisiert!

move "%Ordner%%Datei%" "%temp%\%Datei%"
for /f %%i in ('find /c /v "$$$$"^<"%temp%\%Datei%"') do set /a ZeilenGesamt=%%i
set /a Zehntel=ZeilenGesamt/10
set /a Stufe=1
set /a Z=Zehntel
for /f "delims=" %%i in ('findstr /n "^" "%temp%\%Datei%"') do set "Zeile=%%i" & call :ProcessLine
goto :eof

:ProcessLine
setlocal enabledelayedexpansion
>>"%Ordner%%Datei%" echo(!Zeile:*:=!
endlocal
set /a Z-=1
if %Z%==0 (
if %Stufe% lss 10 >>"%Ordner%\%Datei%" echo MSG^("Programm bei %Stufe%0 %%"^)
set /a Z=Zehntel
set /a Stufe+=1
)
goto :eof

Vielen Dank für die schnelle Hilfe!!!

Grüße
Klette
Bitte warten ..
Mitglied: bastla
14.11.2012 um 15:15 Uhr
Hallo Klette84!

Schön, dass es jetzt passt ...

Magst Du vielleicht noch abschließend die Möglichkeit der "Code"-Formatierung nutzen? Sieht nicht nur schöner aus, sondern ist auch besser zu lesen ...

Grüße
bastla
Bitte warten ..
Mitglied: Klette84
16.11.2012 um 09:59 Uhr
na klar wuste nur nicht wie...

01.
echo. 
02.
set "Ordner=%~dp0" 
03.
for /f "delims=" %%i in ('dir /b "%Ordner%*.mpf"') do (set "Datei=%%i" & call :Label) 
04.
goto :eof 
05.
 
06.
:Label 
07.
echo. 
08.
echo Bitte warten, Programm %Datei% wird aktualisiert! 
09.
 
10.
move "%Ordner%%Datei%" "%temp%\%Datei%" 
11.
for /f %%i in ('find /c /v "$$$$"^<"%temp%\%Datei%"') do set /a ZeilenGesamt=%%i 
12.
set /a Zehntel=ZeilenGesamt/10 
13.
set /a Stufe=1 
14.
set /a Z=Zehntel 
15.
for /f "delims=" %%i in ('findstr /n "^" "%temp%\%Datei%"') do set "Zeile=%%i" & call :ProcessLine 
16.
goto :eof 
17.
 
18.
:ProcessLine 
19.
setlocal enabledelayedexpansion 
20.
>>"%Ordner%%Datei%" echo(!Zeile:*:=! 
21.
endlocal 
22.
set /a Z-=1 
23.
if %Z%==0 ( 
24.
if %Stufe% lss 10 >>"%Ordner%\%Datei%" echo MSG^("Programm bei %Stufe%0 %%"^) 
25.
set /a Z=Zehntel 
26.
set /a Stufe+=1 
27.
28.
goto :eof
Bitte warten ..
Mitglied: Klette84
20.06.2013 um 09:16 Uhr
Hallo,

Das Programm arbeitet einwandfrei! Leider hab ich ein neues Problem und komm mit dem Quellcode nicht zurcht!

Aktuell schreibt die Batch eine neue Datei und erweitert jeweils pro Eintrag um 1 Zeile in der was geschrieben wird!

---> MSG("Programm bei X0%")

Mein neues Problem besteht darin das ich um 2 Zeilen erweitern möchte und zwei unterschiedliche einträge machen möchte...

Q1999 = %STUFE%0
FN 16: F-PRINT TNC:\MELDUNGEN\UHR.txt / SCREEN:


Die neu geschriebene Datei wird bei einer Heidenhain Steuerung verwendet.
Q1999 = "Wert" ---> weist Q-Parameter neuen Wert zu
FN 16: F-Print ruft eine *.txt Datei auf die wiederum auf den Q-Parameter zurückgreift: "Programm bei %3.0LF Prozent", Q1999;

Ich hoffe ihr könnt mir weiterhelfen

Grüße

Klette
Bitte warten ..
Mitglied: bastla
20.06.2013 um 20:46 Uhr
Hallo Klette84!

Wenn Du 2 Zeilen je Datei schreiben willst, sollte es doch genügen, die Zeile 24 auf etwas in der Art von
01.
if %Stufe% lss 10 ( 
02.
    >>"%Ordner%\%Datei%" echo MSG^("Programm bei %Stufe%0 %%"^) 
03.
    >>"%Ordner%\%Datei%" echo MSG^("FN 16: F-PRINT TNC:\MELDUNGEN\UHR.txt / SCREEN:"^) 
04.
)
zu erweitern ...

Grüße
bastla
Bitte warten ..
Mitglied: Klette84
21.06.2013 um 17:00 Uhr
Nee du das geht so nicht ;)

jetzt schreibt er nach jeder Zeile die Gelesen wurde die 2 neuen Einträge hinzu!

Zu dem ist der Syntax auch falsch von den 2 Zeilen die er schreiben soll...

1. Zeile
Q1999 = %Stufe%0

2. Zeile
FN 16: F-PRINT TNC:\MELDUNGEN\UHR.txt / SCREEN:

also ohne MSG("xxxx")



haste ne Idee ???
Bitte warten ..
Mitglied: bastla
21.06.2013, aktualisiert um 21:43 Uhr
Hallo Klette84!

Je Datei müsste das denn doch eher zwischen Zeile 14 und 15 (oder 15 und 16) passieren und dort dann etwa so:
01.
>>"%Ordner%%Datei%" echo Q1999 = %%Stufe%%0 
02.
>>"%Ordner%%Datei%" echo FN 16: F-PRINT TNC:\MELDUNGEN\UHR.txt / SCREEN:
Grüße
bastla
Bitte warten ..
Mitglied: Klette84
26.06.2013 um 07:59 Uhr
Ich hab das Problem gefunden, warum er mir nach jeder Zeile die neuen Einträge macht...

Richtig muß es so geschrieben werden:

01.
 
02.
setlocal 
03.
CLS 
04.
echo. 
05.
set "Ordner=%~dp0" 
06.
for /f "delims=" %%i in ('dir /b "%Ordner%*.h"') do (set "Datei=%%i" & call :Label) 
07.
echo. 
08.
echo Alle Datein bearbeitet.  
09.
echo. 
10.
PAUSE 
11.
goto :TOP 
12.
 
13.
:Label 
14.
echo. 
15.
echo    Bitte warten, Programm %Datei% wird aktualisiert! 
16.
 
17.
move "%Ordner%%Datei%" "%temp%\%Datei%" 
18.
for /f %%i in ('find /c /v "$$$$"^<"%temp%\%Datei%"') do set /a ZeilenGesamt=%%i 
19.
set /a Zehntel=ZeilenGesamt/10 
20.
set /a Stufe=1 
21.
set /a Z=Zehntel 
22.
for /f "delims=" %%i in ('findstr /n "^" "%temp%\%Datei%"') do set "Zeile=%%i" & call :ProcessLine 
23.
goto :eof 
24.
 
25.
:ProcessLine 
26.
setlocal enabledelayedexpansion 
27.
>>"%Ordner%%Datei%" echo(!Zeile:*:=! 
28.
endlocal 
29.
set /a Z-=1 
30.
if %Z%==0 (  
31.
	>>"%Ordner%%Datei%" echo Q1999 = %Stufe%0 
32.
	>>"%Ordner%%Datei%" echo FN 16: F-PRINT TNC:\MELDUNGEN\UHR.txt / SCREEN: 
33.
    	set /a Z=Zehntel 
34.
    	set /a Stufe+=1 
35.
36.
goto :eof


Eine kleine Knobelfrage hätte ich noch.

Wie kann ich das Programm so umschreiben das er mir auf gar kein fall in den ersten 15 Zeilen ein Eintrag schreibt?

Hat den Hintergrund das am Anfang in der Datei diverse Sätze stehen die nicht getrennt werden dürfen. Danach kommen nur Punktangaben wo neue Einträge da zwischen passen.

Grüße

Klette
Bitte warten ..
Mitglied: bastla
26.06.2013 um 14:18 Uhr
Hallo Klette84!

Ungetestet etwa so:
01.
setlocal 
02.
set /a Ignore=15 
03.
CLS 
04.
echo. 
05.
set "Ordner=%~dp0" 
06.
for /f "delims=" %%i in ('dir /b "%Ordner%*.h"') do (set "Datei=%%i" & call :Label) 
07.
echo. 
08.
echo Alle Datein bearbeitet.  
09.
echo. 
10.
PAUSE 
11.
goto :TOP 
12.
 
13.
:Label 
14.
echo. 
15.
echo    Bitte warten, Programm %Datei% wird aktualisiert! 
16.
 
17.
move "%Ordner%%Datei%" "%temp%\%Datei%" 
18.
for /f %%i in ('find /c /v "$$$$"^<"%temp%\%Datei%"') do set /a ZeilenGesamt=%%i-%Ignore% 
19.
set /a Zehntel=ZeilenGesamt/10 
20.
set /a Stufe=1 
21.
set /a Z=Zehntel 
22.
set /a ZNr=1 
23.
for /f "delims=" %%i in ('findstr /n "^" "%temp%\%Datei%"') do set "Zeile=%%i" & call :ProcessLine 
24.
goto :eof 
25.
 
26.
:ProcessLine 
27.
setlocal enabledelayedexpansion 
28.
>>"%Ordner%%Datei%" echo(!Zeile:*:=! 
29.
endlocal 
30.
set /a ZNr+=1 
31.
if %ZNr% leq %Ignore% goto :eof 
32.
set /a Z-=1 
33.
if %Z%==0 (  
34.
	>>"%Ordner%%Datei%" echo Q1999 = %Stufe%0 
35.
	>>"%Ordner%%Datei%" echo FN 16: F-PRINT TNC:\MELDUNGEN\UHR.txt / SCREEN: 
36.
    	set /a Z=Zehntel 
37.
    	set /a Stufe+=1 
38.
39.
goto :eof
Grüße
bastla
Bitte warten ..
Neuester Wissensbeitrag
Festplatten, SSD, Raid

12TB written pro SSD in 2 Jahren mit RAID5 auf Hyper-VServer

Erfahrungsbericht von Lochkartenstanzer zum Thema Festplatten, SSD, Raid ...

Ähnliche Inhalte
Batch & Shell
gelöst Mittels Batch jede Zeile einer Textdatei prüfen (4)

Frage von Peter32 zum Thema Batch & Shell ...

Batch & Shell
gelöst Kl. Frage: Log-File schreiben per Batch (3)

Frage von Yauhun zum Thema Batch & Shell ...

Heiß diskutierte Inhalte
Windows Userverwaltung
Ausgeschiedene Mitarbeiter im Unternehmen - was tun mit den AD Konten? (34)

Frage von patz223 zum Thema Windows Userverwaltung ...

LAN, WAN, Wireless
gelöst Server erkennt Client nicht wenn er ausserhalb des DHCP Pools liegt (28)

Frage von Mar-west zum Thema LAN, WAN, Wireless ...

LAN, WAN, Wireless
FritzBox, zwei Server, verschiedene Netze (21)

Frage von DavidGl zum Thema LAN, WAN, Wireless ...

Viren und Trojaner
Aufgepasst: Neue Ransomware Goldeneye verbreitet sich rasant (20)

Link von Penny.Cilin zum Thema Viren und Trojaner ...