koluschkib
May 25, 2010
view6037
view15
1
Goto Top

Gruppen anlegen aus csv datei und user hinzufügen

GermansolvedQuestionVB for ApplicationsDevelopment

hey admin freunde

vielleicht kann einer von euch mal dieses script sich mal anschauen und mir sagen wo der fehler liegt

dieses script liest aus einer .csv datei die benutzer und gruppen aus und legt sie im AD an. noch dazu werden benutzerordner erstellt und im netzwerk freigegebene.

das problem was ich habe, sind dieses shit gruppen.
in der csv datei sind natürlich einige gruppen doppelt vorhanden, letzt endlich steht dort nur, das der user xy denn gruppen V und Z zugeordnet sind. problem ist dies, dass er zwar die gruppen anlegt, aber immer nur einen benutzer hinzufügt. dabei sollte zb die gruppe Z 5Mitglieder haben.
ich bin schon am verzweifeln und es kotzt mch langsam an. ich brauche keine nutzlosen tipps, dass ich die lösung in der script-center.chm datei finden also spart euch die mühe, es mir mitzuteilen. ich hab schon alles möglich probiert, vieles verscuht und doch am ende gescheiter.
hab schon hier, dass problem gepostet ob es ne möglichkeit gäbe, irgendwie diese Gruppen erstellen so abzufangen, dass das script es selbst checkt, das die gruppe bereits existiert. aber außer gulasch und dem tollen tipp "im script-center.chm" findest du die lösung, kam nichts brauchbares heraus.
im netz finden man hilfen, wie man user in gruppen addet. starte ich das script kriege ich an immer an der selben stelle nen fehler, dabei kann es nicht falsch sein... denn es steht sogar in dieser script-center drine von der jeder hier so schwärmt face-smile

dies ist der code

Dim objDomain, objOU, objUser, objGroup
Dim fso, f, Zeile, Feld
Dim objFSO, objFolder, strComputer, objWMIService, objNewShare

Set fso = CreateObject("Scripting.FileSystemObject")  
Set f = fso.OpenTextFile ("c:\user.txt",1,0)  

Do while not f.AtEndOfLine
Zeile = f.readLine
Feld = split(Zeile,";")  
Vorname = Feld(0)
Nachname = Feld(1)
Abteilung = Feld(2)
Gruppe1 = Feld(3)
Gruppe2 = Feld(4)
Gruppe3 = Feld(5)
Gruppe4 = Feld(6)
Gruppe5 = Feld(7)

 
Set objOU = GetObject("LDAP://cn=users,dc=testad,dc=int")  
Set objUser = objOU.Create("user", "CN=" & Vorname & " " & Nachname)  
objUser.Put "sAMAccountName", Nachname  
objUser.Put "displayName", Vorname & " " & Nachname  
objUser.Put "givenName", Vorname  
objUser.Put "sn", Nachname  
objUser.Put "description", Abteilung  
'objUser.Put "userAccountControl", 66082  
objUser.Put "userPrincipalName", left(Vorname,3) & left(nachname,2) & "@testAD.int"  
objUser.SetInfo




Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
Set objGroup = objOU.Create("Group", "cn=" & Gruppe2)  
Set objGroup = objOU.Create("Group", "cn=" & Gruppe3)  
Set objGroup = objOU.Create("Group", "cn=" & Gruppe4)  
Set objGroup = objOU.Create("Group", "cn=" & Gruppe5)  

On Error Resume Next

objGroup.SetInfo
objGroup.Add objUser.ADsPath


'Ordner werden für denn Benutzer angelegt, dabei wird der Nachname als Ordnernameverwendet  
Set objFSO = CreateObject("Scripting.FileSystemObject")  
Set objFolder = objFSO.CreateFolder("C:\Freigaben\" &Nachname)  

Dim File_Share
File_Share = 0
Dim MAXIMUM_CONNECTIONS
MAXIMUM_CONNECTIONS = 25


strComputer = "."  
Set objWMIService = GetObject("winmgmts:" _  
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  

Set objNewShare = objWMIService.Get("Win32_Share")  

errReturn = objNewShare.Create _
("C:\Freigaben\" &Nachname, ""&Nachname, File_Share, _  
    MAXIMUM_CONNECTIONS, "Benutzerordner")  
Loop

der fehler steckt irgendwo zwischen zeile 35 und 47.
nehme ich das "ON ERROR RESUME NEXT"
werden als erstes die objGroup = objOU.Create befehle bemängelt, lasse ich die weg, krieg ich ne meldung dass objGroup.ADD ein unbekannter befehl ist.
usw usw... ein teufelskreis

mfg

koluschkiB
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 143493

Url: https://administrator.de/contentid/143493

Printed on: April 26, 2024 at 03:04 o'clock

15 Comments
Latest comment
Goto Top
Member: bastla
bastla May 25, 2010 at 19:22:00 (UTC)
Goto Top
Hallo koluschkiB!

Weil Du dermaßen freundlich fragst, werde ich versuchen, Dir Hilfestellung in Form von Hinweisen auf Beispiele anzubieten (ohne eine ".chm" - obwohl es hier auch eine solche gäbe face-wink):
http://blogs.technet.com/b/heyscriptingguy/archive/2005/09/21/how-can-i ...
http://blogs.technet.com/b/heyscriptingguy/archive/2005/11/23/how-can-i ...

Auf Basis dessen, was dort gezeigt wird, könntest Du dann zB eine Funktion, die prüft, ob es eine bestimmte Gruppe schon gibt, verwenden und, abhängig vom Ergebnis, die Gruppe neu erstellen oder nur per "GetObject" auf die schon bestehende Gruppe zugreifen - im einfacheren Fall (Ziel-OU bekannt, keine Notwendigkeit, im gesamten AD auf Vorhandensein einer gleichnamigen Gruppe zu prüfen):
Function GroupExists(Group, OU)
'OU wird als Obejkt übergeben; es interessieren nur die enthaltenen Gruppen  
OU.Filter = Array("group")  
'Default: Gruppe noch nicht vorhanden  
GroupExists = False
'Alle in der OU enthaltenen Gruppen durchgehen  
For Each objGroup in OU
    'klein geschriebenen Gruppennamen der betrachteten Gruppe  
    'mit klein geschriebenem übergebenen Gruppennamen vergleichen  
    If LCase(objGroup.sAMAccountName) = LCase(Group) Then
        'bei Übereinstimmung gibt es die Gruppe bereits ...  
        GroupExists = True
        '... und es müssen die weiteren Gruppen nicht mehr geprüft werden  
        Exit For
    End If
Next
End Function
Verwenden lässt sich diese Funktion etwa so:
If GroupExists("GruppeZ", objOU) Then  
    'Gruppe nur referenzieren  
Else
    'Gruppe erzeugen  
End If
Grüße
bastla

P.S.:
das problem was ich habe, sind dieses shit gruppen
Es ist ja wirklich nicht einzusehen, dass Du Dich als Anfänger anstatt mit Sicherheitsgruppen gleich mit "shit"-Gruppen herumschlagen sollst ... face-wink
Member: koluschkiB
koluschkiB May 26, 2010 at 07:02:00 (UTC)
Goto Top
funktioniert nicht...

wenn ich die funktion meinem script anpasse, habe ich gleich in der ersten zeile nen fehler "GroupExists" = Typen unverträglichkeit. wieso auch immer das so ist...

und so sieht es in etwa aus

If GroupExist("Gruppe1", objOU) Then  
    objGroup.Add objUser.ADsPath
Else
    Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
	objGroup.Add objUser.ADsPath
End If

an sich ist es logisch, wenn gruppe1 existiert den nötigen user hinzufügen. wenn gruppe1 nicht existiert, anlegen und dann den vogel dazu adden. leider ist theorie nicht mit der praxis zu vergleichen. oder habe ich da grade nen denkfehler?

meine idee, die ich hatte war folgenedes:

Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
if objGroupExists Then
objGroup.SetInfo
objGroup.Add objUser.ADsPath
else ON Error Resume Next
End If

und siehe da es funktioniert face-smile
endlich ein erfolgserlebnis ^^ er legt die gruppe an, und fügt in die gruppe die richtigen user hinzu... juhuuuuu

dennoch danke, die nächsten sorgen, werden folgen. leider ist die aufgabe vollständig abgearbeitet. kleinigkeiten fehlen noch. aber das wird schon klappen

danke und gruß

koluschkiB
Member: bastla
bastla May 26, 2010 at 07:23:41 (UTC)
Goto Top
Hallo koluschkiB!
If GroupExist("Gruppe1", objOU) Then  
    objGroup.Add objUser.ADsPath
Else
    Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
	objGroup.Add objUser.ADsPath
End If
an sich ist es logisch, wenn gruppe1 existiert den nötigen user hinzufügen. wenn gruppe1 nicht existiert, anlegen und dann den vogel dazu adden. leider ist theorie nicht mit der praxis zu vergleichen. oder habe ich da grade nen denkfehler?
Der Ablauf wäre soweit ok, allerdings kannst Du den User im ersten Fall nur hinzufügen, wenn Du bereits die Gruppe als Objekt zur Verfügung hast, was aber (noch) nicht der Fall ist - daher wäre noch ein
Set objGroup = GetObject ...
erforderlich.
Das zweite Script macht eigentlich genau das Verkehrte - wenn Du die Gruppe (gerade eben) erstellt hast, brauchst Du nicht mehr zu prüfen, ob es sie schon gibt - die Prüfung soll ja eben verhindern, dass Du die Gruppe anzulegen versuchst, wenn sie bereits vorhanden ist ...

Grüße
bastla
Member: koluschkiB
koluschkiB May 26, 2010 at 07:52:41 (UTC)
Goto Top
hey bastla


If GroupExist("Gruppe1", objOU) Then  
>     objGroup.Add objUser.ADsPath
> Else
>     Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
> 	objGroup.Add objUser.ADsPath
> End If
>

das problem hatte ich eben schon ---> Fehler beim Ausführen
Typen unverträglichkeit mit GroupExists

wo soll denn deiner meiner nach nach das

Set objGroup = ...

stehen?vor die IF anweisung?

quasi so?
Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
If GroupExists("Gruppe1", objOU) Then  
    objGroup.Add objUser.ADsPath
Else
    Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
	objGroup.Add objUser.ADsPath
End If

---> Fehler Typen unverträglichkeit GroupExists

stehe bisschena uf dem schlauch und checks nicht so ganz was du meinst

gruß

koluschki
Member: bastla
bastla May 26, 2010 at 10:28:28 (UTC)
Goto Top
Hallo koluschkiB!

Das sollte (zB ab Zeile 33 Deines ursprünglichen Scripts) etwa so aussehen (wobei sich natürlich für 5 Gruppen eine Schleife anbieten würde):
If GroupExists(Gruppe1, objOU) Then
    Set objGroup = GetObject("LDAP://cn=" & Gruppe1 & ",cn=Users,dc=testad,dc=int")  
Else
    Set objGroup = objOU.Create("Group", "cn=" & Gruppe1)  
    objGroup.SetInfo
End If

objGroup.Add objUser.ADSPath
Grüße
bastla
Member: koluschkiB
koluschkiB May 26, 2010 at 11:53:36 (UTC)
Goto Top
hey bastla,

hab das fragment in mein script eingebaut, aber wie schon eben zig mal geschrieben, kriege ich beim ausführen des Scripts folgenden fehler

typenunverträglichkeit "GroupExists"

somit hilf mir das nicht wirklich weiter

danke

koluschki
Member: bastla
bastla May 26, 2010 at 13:13:01 (UTC)
Goto Top
Hallo koluschkiB!

Ich weiß ja nun nicht, wie und wo Du das eingebaut hast, aber so sollte es auf jeden Fall funktionieren:
Option Explicit

Dim OU, objDomain, objOU, objUser, objGroup
Dim fso, f, Zeile, Feld, Vorname, Nachname, Abteilung, i
Dim objFolder, strComputer, objWMIService, objNewShare, errReturn

OU = "cn=users,dc=testad,dc=int"  
Set objOU = GetObject("LDAP://" & OU)  

Const File_Share = 0
Const MAXIMUM_CONNECTIONS = 25

strComputer = "."  
Set objWMIService = GetObject("winmgmts:" _  
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  
Set objNewShare = objWMIService.Get("Win32_Share")  

Set fso = CreateObject("Scripting.FileSystemObject")  
Set f = fso.OpenTextFile("c:\user.txt",1,0)  

Do While Not f.AtEndOfLine
    Zeile = f.readLine
    Feld = split(Zeile,";")  
        Vorname = Feld(0)
        Nachname = Feld(1)
        Abteilung = Feld(2)
'        Gruppen werden in Schleife direkt angesprochen  
'        Gruppe1 = Feld(3)  
'        Gruppe2 = Feld(4)  
'        Gruppe3 = Feld(5)  
'        Gruppe4 = Feld(6)  
'        Gruppe5 = Feld(7)  

    Set objUser = objOU.Create("user", "CN=" & Vorname & " " & Nachname)  
        objUser.Put "sAMAccountName", Nachname  
        objUser.Put "displayName", Vorname & " " & Nachname  
        objUser.Put "givenName", Vorname  
        objUser.Put "sn", Nachname  
        objUser.Put "description", Abteilung  
        'objUser.Put "userAccountControl", 66082  
        objUser.Put "userPrincipalName", left(Vorname,3) & left(nachname,2) & "@testAD.int"  
    objUser.SetInfo

    For i = 3 To 7 'alle Gruppen bearbeiten  
        If Feld(i) <> "" Then  
            If GroupExists(Feld(i), objOU) Then
                Set objGroup = GetObject("LDAP://cn=" & Feld(i) & "," & OU)  
            Else
                Set objGroup = objOU.Create("Group", "cn=" & Feld(i))  
                objGroup.Put "sAMAccountName", Feld(i)  
                objGroup.SetInfo
            End If
            objGroup.Add objUser.ADSPath
        End If
    Next

    'Ordner werden für denn Benutzer angelegt, dabei wird der Nachname als Ordnername verwendet  
    Set objFolder = fso.CreateFolder("C:\Freigaben\" & Nachname)  

    errReturn = objNewShare.Create _
        ("C:\Freigaben\" & Nachname, Nachname, File_Share, _  
        MAXIMUM_CONNECTIONS, "Benutzerordner")  
Loop

Function GroupExists(Group, OU)
'OU wird als Objekt übergeben; es interessieren nur die enthaltenen Gruppen  
OU.Filter = Array("group")  
'Default: Gruppe noch nicht vorhanden  
GroupExists = False
'Alle in der OU enthaltenen Gruppen durchgehen  
For Each objGroup in OU
    'klein geschriebenen Gruppennamen der betrachteten Gruppe  
    'mit klein geschriebenem übergebenen Gruppennamen vergleichen  
    If LCase(objGroup.sAMAccountName) = LCase(Group) Then
        'bei Übereinstimmung gibt es die Gruppe bereits ...  
        GroupExists = True
        '... und es müssen die weiteren Gruppen nicht mehr geprüft werden  
        Exit For
    End If
Next
End Function
Ein paar Anmerkungen:
  • Wenn Du in VBS Variablen deklarierst, dann nur nach einem "Option Explicit" (und natürlich alle).
  • Mehrfach verwendete Objekte immer wieder in einer Schleife zu erstellen ist wenig sinnvoll.
  • Es genügt ein "FileSystemObject" ("fso" vs "objFSO").
  • Öfter verwendete Strings (zB den Pfad der OU) vorweg in eine Variable oder sogar Konstante schreiben - macht das Script leichter anpassbar.
  • Gleiches gilt für konstante Werte wie etwa "File_Share".
  • Auch für das Erstellen der Benutzerordner wäre vorweg eine Prüfung, ob der Ordner bereits existiert, sinnvoll.
  • Wer hatte eigentlich die Idee, für jeden Ordner eine eigene Freigabe zu verwenden?
  • Einrückungen machen einen Code übersichtlicher.

Grüße
bastla
Member: koluschkiB
koluschkiB May 26, 2010 at 14:13:38 (UTC)
Goto Top
hey bastla,

danke für dein ausführliches script.
ich musste ein paar sachen ncoh ergänzen, wie zb diese passwort generierung. naja hab die variable passwort gesetzt usw.
er startet zwar problemlos das scritp und legt die ersten benutzer an, aber dann kommt die fehlerung dass ein objekt bereits vorhanden ist.
ich geh davon aus, dass er ne namen vergeben will, der schon da ist

ich hab das scritp so angepasst
Option Explicit

Dim OU, objDomain, objOU, objUser, objGroup
Dim fso, f, Zeile, Feld, Vorname, Nachname, Abteilung, i, Passwort
Dim objFolder, strComputer, objWMIService, objNewShare, errReturn

OU = "cn=users,dc=testad,dc=int"  
Set objOU = GetObject("LDAP://" & OU)  

Const File_Share = 0
Const MAXIMUM_CONNECTIONS = 25

strComputer = "."  
Set objWMIService = GetObject("winmgmts:" _  
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  
Set objNewShare = objWMIService.Get("Win32_Share")  

Set fso = CreateObject("Scripting.FileSystemObject")  
Set f = fso.OpenTextFile("c:\user.csv",1,0)  

Do While Not f.AtEndOfLine
Zeile = f.readLine
Feld = split(Zeile,";")  
Vorname = Feld(0)
Nachname = Feld(1)
Abteilung = Feld(2)
'        Gruppen werden in Schleife direkt angesprochen  
'        Gruppe1 = Feld(3)  
'        Gruppe2 = Feld(4)  
'        Gruppe3 = Feld(5)  
'        Gruppe4 = Feld(6)  
'        Gruppe5 = Feld(7)  


Passwort = left(Vorname,3)&left(Nachname,2)&"1234%"  
Passwort = LCase(passwort)

Set objUser = objOU.Create("user", "CN=" & Vorname & " " & Nachname)  
objUser.Put "sAMAccountName", Nachname  
objUser.Put "displayName", Vorname & " " & Nachname  
objUser.Put "givenName", Vorname  
objUser.Put "sn", Nachname  
objUser.Put "description", Abteilung  
objUser.Put "userPrincipalName", left(Vorname,3) & left(nachname,2) & "@testAD.int"  
objUser.SetInfo
objUser.SetPassword Passwort
objUser.Put "userAccountControl", 544  
objUser.Put "pwdLastSet", 0  
objUser.SetInfo

For i = 3 To 7 'alle Gruppen bearbeiten  
If Feld(i) <> "" Then  
If GroupExists(Feld(i), objOU) Then
Set objGroup = GetObject("LDAP://cn=" & Feld(i) & "," & OU)  
Else
Set objGroup = objOU.Create("Group", "cn=" & Feld(i))  
objGroup.Put "sAMAccountName", Feld(i)  
objGroup.SetInfo
End If
objGroup.Add objUser.ADSPath
End If
Next

'Ordner werden für denn Benutzer angelegt, dabei wird der Nachname als Ordnername verwendet  
Set objFolder = fso.CreateFolder("C:\Freigaben\" & Nachname)  
errReturn = objNewShare.Create _
    ("C:\Freigaben\" & Nachname, Nachname, File_Share, _  
    MAXIMUM_CONNECTIONS, "Benutzerordner")  
Loop

Function GroupExists(Group, OU)
'OU wird als Objekt übergeben; es interessieren nur die enthaltenen Gruppen  
OU.Filter = Array("group")  
'Default: Gruppe noch nicht vorhanden  
GroupExists = False
'Alle in der OU enthaltenen Gruppen durchgehen  
For Each objGroup in OU
    'klein geschriebenen Gruppennamen der betrachteten Gruppe  
    'mit klein geschriebenem übergebenen Gruppennamen vergleichen  
    If LCase(objGroup.sAMAccountName) = LCase(Group) Then
        'bei Übereinstimmung gibt es die Gruppe bereits ...  
        GroupExists = True
        '... und es müssen die weiteren Gruppen nicht mehr geprüft werden  
        Exit For
    End If
Next
End Function

die fehlermeldung haut raus, dass in der zeile 58 der fehler ist "das objekt ist bereits vorhanden"

in der csv datei, sind natürlich eineige gruppen doppelt, bzw, verschiedene user in der selben gruppe.
was die freigegeben ordner angeht, istd as nopch nicht ganz fertig. die berechtigungen müssen noch gesetzt werden.
in der aufgabenstellung heisst es, jedem benutzer soll eine verzeichnis eingerichtet werden, welches für denn netzwerkzugriff eingerichtet wird

gruß

koluschki
Member: bastla
bastla May 26, 2010 at 14:28:40 (UTC)
Goto Top
Hallo koluschkiB!
"das objekt ist bereits vorhanden"
... klingt nach Resten eines vorigen Tests - sollte aber gerade bei Gruppen (also in Zeile 58) nicht passieren, da ja deren Existenz vorweg geprüft wird.

Zum Testen kannst Du zwischen Zeile 52 und 53 zB
WScript.Echo Nachname, Feld(i)
einfügen und das Script aus einer CMD-Shell mit
cscript //nologo C:\Useranlage.vbs
testen - so kannst Du nachvollziehen, bei welchem User und welcher Gruppe der Fehler entsteht.
in der aufgabenstellung heisst es, jedem benutzer soll eine verzeichnis eingerichtet werden, welches für denn netzwerkzugriff eingerichtet wird
Dazu würde es aber reichen, wenn Du "C:\Freigaben" frei gibst und mit passenden NTFS-Rechten dafür sorgst, dass auf den darunter liegenden User-Ordner nur noch der User selbst und zB die Gruppe "Administratoren" zugreifen können.

Grüße
bastla
Member: koluschkiB
koluschkiB May 26, 2010 at 14:33:01 (UTC)
Goto Top
hey bastla´,

hab das script nochmal ausgeführt, und geschaut wie wo was anders ist und woran es liegen könnte

hab den fehler gefunden face-smile
er war bei dem erstellen von denn Benutzerordnern. dort war ne Const gesetzt und keine variable.
eben so hab eich gesehen, dass in deinem code meine lieblingsfehler waren "" und & hat an einer stelle gefehlt.

super geile sache, die gruppen werden angelegt. die user werden hin zu gefügt.

danke face-smile

koluschkiB
Member: koluschkiB
koluschkiB May 26, 2010 at 14:34:14 (UTC)
Goto Top
ich hab den fehler gefunden face-smile
ursache habe ich eben schon an einer anderen stelle hier erklärt

an denn resten früherer test kann es nciht liegen, da ich alles gandenlos gecleant habe. hab das script mittlerweile bestimmt schon 100000 ausgeführt und weiss, was wo weg muss

nochmal zu denn ordnern, nur der Admin und der "Ordnerinhaber" sollen zugriff auf denn ordner kriegen. alle anderen sollen ausgesperrt sein
schaue aber ob ich ne lösung irgendwo dafür finden

danke

koluschki
Member: bastla
bastla May 26, 2010 at 14:44:21 (UTC)
Goto Top
Hallo koluschkiB!

Na schön ... face-smile

Da ich das ja offensichtlich übersehen haben muss:
dass in deinem code meine lieblingsfehler waren "" und & hat an einer stelle gefehlt.
Wo (in welcher Zeile meines Entwurfs) haben denn die Teile gefehlt?

[Edit]
Falls Du
""&Nachname
gemeint haben solltest: Es ist ziemlich sinnfrei, einen Leerstring mit einer Variablen zusammenzufügen - das Ergebnis ist wieder nur der Inhalt der Variablen ...
[/Edit]

Grüße
bastla

P.S.: Wie sieht denn nun Dein funktionierendes Script aus?
Member: koluschkiB
koluschkiB May 27, 2010 at 06:26:03 (UTC)
Goto Top
morgen bastla,

genau das meinte ich mit den "" und &. ich habs nur mit meinem script so bisschen vergliechen und dies fiel mir halt auf.
aber die hauptursache, dass das script nen fehler rein gehauen hat. war bei der ordner erstellung die variable bzw in deinem script die const File_SHare und Maximum_Connection. hab aus const dim gemacht und zack, lief es problemlos durch. frag mich nicht, wieso das so war. aber es hat mich gefreut, den fehler auch selbst gefunden zu haben face-smile ...ein erfolgserlebniss face-wink

das script läuft super. es ist ein paar zeilen kürzer, musst ein paar sachen ergänzen, wie zb mit dem PW generieren aus vor- und nachname. aber das lief problemlos.
jetzt sind es nur noch ein paar kleinigkeiten die mir in dem script fehlen, aber da mach eich mich ehute ans werk
nochmal danke für alles

gruß

koluschkiB
Member: bastla
bastla May 27, 2010 at 07:09:03 (UTC)
Goto Top
Hallo koluschkiB!
bei der ordner erstellung die variable bzw in deinem script die const File_SHare und Maximum_Connection. hab aus const dim gemacht und zack, lief es problemlos durch. frag mich nicht, wieso das so war.
Der Unterschied zwischen "Const" (kannst Du im gesamten Script nur einmal machen - daher auch gleich am Anfang) und "Dim" (ist mehrmals möglich) kommt eigentlich nur zum Tragen, wenn Du den jeweiligen Befehl innerhalb einer Schleife platzierst - den Wert von "File_Share" und "MAXIMUM_CONNECTIONS" willst Du ja ohnehin zwischendurch nicht mehr ändern (dazu müssten es Variable und daher per "Dim" deklariert sein) ...

Grüße
bastla
Member: koluschkiB
koluschkiB May 27, 2010 at 13:24:39 (UTC)
Goto Top
hey bastla

die werte können ja so bleiben, durch testen usw. hab eich halt gesehen, dass es mit Const eben nicht geht und er mir ne Fehlermeldung raushaut.

trotzdem danke für alles
und weiterhin gutes gelingen face-smile

ich mach mich weiter an meine aufgabe, ordnerberechtigungen setzen face-smile

gruß und danke

koluschkiB
GermansolvedQuestionVB for ApplicationsDevelopment
Hotly discussed
gleixnerdCheck of ZFW Firewallgleixnerd - 5 Comments