Pfadangaben aus Datei filtern und für Copy Job verwenden

@for /f "delims=" %i in ('findstr "\\" Playlist.xxx') do @if not exist "Y:\Music\%~nxi" @copy "%i" Y:\Music\ >nul  

@for /f "delims=" %i in ('findstr "\\" Playlist.xxx')  

for /f "delims=" %%i in ('findstr /v "^#" Playlist.xxx') do if not exist "Y:\Music\%%~nxi" copy "%%i" Y:\Music\ >nul  

@echo off & setlocal
set "Target=Y:\Music"  
set "PlIn=C:\Dokumente und Einstellungen\Username\Eigene Dateien\Eigene Musik\Whatever\Playlist.xxx"  
set "PlOut=%Target%\Playlist.yyy"  

for /f "delims=" %%i in ('findstr /v "^#" "%PlIn%"') do if not exist "%Target%\%%~nxi" copy "%%i" "%Target%\" >nul  

...

@echo off & setlocal

set "Target=Y:\Music"  
::Default für Playlist
set "PlIn=C:\Dokumente und Einstellungen\Username\Eigene Dateien\Eigene Musik\Whatever\Playlist.xxx"  
set "PlOutExt=.yyy"  
set "HeaderM3U=#EXTM3U"  

::Falls Playlist als Argument übergeben wurde, diese(s) verwenden
if not [%1]== set "PlIn=%~1"  

if not exist "%PlIn%" echo Playlist "%PlIn%" nicht gefunden! & goto :eof  

::Einzeiligen Header einlesen
set /p Header=<"%PlIn%"  
::Kontrolle Playlistformat - kann natürlich auch unterbleiben
if not "%Header%"=="%HeaderM3U%" echo Playlist-Format nicht OK! & goto :eof  

::Codepage umstellen (aktuelle CP zwischenspeichern)
for /f "tokens=2 delims=:." %%i in ('chcp') do set "CP=%%i"  
chcp 1252>nul

::Bei Bedarf Zielordner erzeugen
if not exist "%Target%" md "%Target%"  

::Pfad für neue Playlist (Dateiname und -typ bleiben gleich) festlegen ...
for %%i in ("%PlIn%") do set "PlNew=%Target%\%%~nxi"  

::... und Header in neue Playlist schreiben
echo %Header%>"%PlNew%"  

::Ausgangs-Playlist ab Zeile 2 (also nach dem Header) auslesen und verarbeiten
for /f "usebackq skip=1 delims=" %%i in ("%PlIn%") do set "Line=%%i" & call :ProcessLine "%%i"  

::Alternative Playlist erzeugen
call :MakePlaylist_yyy

::Codepage wieder auf ursprünglichen Wert setzen
chcp %CP%>nul

::Hauptprogramm Ende
goto :eof


:ProcessLine
::Wenn Zeile nicht mit "#" beginnt, muss es ein Dateipfad sein 
if not %Line:~0,1%==# goto :CopyIt
::"#"-Zeile zwischenspeichern (Ausgabe in neue Playlist erst nach erfolgreicher Kopie der Musikdatei) 
set "Info=%Line%"  
goto :eof

:CopyIt
::Ist die zu kopierende Musikdatei vorhanden?
if not exist %1 echo %1 nicht gefunden! & goto :eof

::Ist die zu kopierende Musikdatei bereits im Zielordner vorhanden?
if exist "%Target%\%~nx1" echo %1 bereits in "%Target%" vorhanden - nicht kopiert! & goto :eof  

::Kopie durchführen und, wenn kein Fehler gemeldet wird, weiter zum Schreiben des Playlist-Eintrages
copy %1 "%Target%\%~nx1" >nul 2>nul && goto :CopyOK  
echo %1 konnte nicht kopiert werden! & goto :eof

:CopyOK
::Eintrag in neue Playlist; da im Zielverzeichnis "flat" erstellt, als "Pfad" nur Dateiname 
(echo %Info%)>>"%PlNew%"  
(echo %~nx1)>>"%PlNew%"  
goto :eof

:MakePlaylist_yyy
::Pfad und Dateiname (mit Typ %PlOutExt%) der alternativen Playlist festlegen
for %%i in ("%PlNew%") do set "PlOut=%%~dpni%PlOutExt%"  

echo ^<MUSICFOLDERS^>>"%PlOut%"  
echo ^<MUSICFOLDER DIR="" /^>>>"%PlOut%"  
echo ^</MUSICFOLDERS^>>>"%PlOut%"  

::Daten aus neuer Playlist verwenden
for /f "delims=" %%i in ('findstr /V "^#" "%PlNew%"') do (  
    echo ^<ENTRY TITLE="" TYPE="1"^>>>"%PlOut%"  
    echo ^<LOCATION DIR="%%~pi" FILE="%%~nxi" VOLUME="%%~di" /^>>>"%PlOut%"  
    echo ^<EXTDATA /^>>>"%PlOut%"  
    echo ^</ENTRY^>>>"%PlOut%"  
)
goto :eof

CopyMusic.cmd > D:\CopyMusicLog.txt

CopyMusic.cmd "D:\Andere Playlist.m3u"  

@echo off 
set nrlen=3

chcp 1252 >NUL
set "nrvorl="  
set i=0
:dazu
set nrvorl=%nrvorl%0
set /a i=%i%+1
if %i% lss %nrlen% goto:dazu

set name="%~1"  

if [%name%]==[""] set /p name=Name der Playlist:  
for /F "delims=" %%a in ('dir /b /a-D %name%') do (  
set "filename=%%~na"  
set "playlistpath=%%~dpa"  
if ["%~1"]==[""] (set fullname="%%~fa" & set playlisttype=%%~xa) else (set fullname="%~1" & set "playlistpath=%~dp1" & set playlisttype=%~x1)  
)
set playlistpath=%playlistpath:~0,-1%

set "pfad=%playlistpath%\%filename%"  
set nummer=1
if /i not exist "%pfad%\NUL" md "%pfad%" 2>NUL  
echo Dateien aus der Playlist werden kopiert:
echo.
REM aalte zeile: FOR /F "eol=# tokens=1 delims=" %%A in ('type %fullname%') do call:nrkopier "%%A"  

echo Playlisttyp: %playlisttype:~1%
if /i "%playlisttype%" equ ".m3u" ((for /f "delims=" %%A in ('findstr /V "^#EXT" %fullname%') do call:nrkopier "%%A") & goto:copyok)  
if /i "%playlisttype%" equ ".pls" ((for /f "tokens=2* delims==" %%A in ('findstr "^File" %fullname%') do call:nrkopier "%%A") & goto:copyok)  
echo Unbekannter Playlisttyp

:copyok
echo.
chcp 850 >NUL
pause
goto:eof

:nrkopier
set anummer=%nrvorl%%nummer%
call set anummer=%%anummer:~-%nrlen%%%
chcp 850 >NUL
echo %anummer%: "%~n1"  
chcp 1252 >NUL
copy "%~1" "%pfad%\%anummer% %~nx1" /Y >NUL||(copy "%playlistpath%\%~1" "%pfad%\%anummer% %~nx1" /Y >NUL||(echo Fehler beim Kopieren && Pause))  
set /a nummer=%nummer%+1
goto:eof

for /f "tokens=1,2 delims=;" %%i in (Pfade.ini) do @echo robocopy "%%i" "%%j"