Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen (A bis Z)

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

VBS Script um Emailadressen aus einer TXT, CSV oder XLS-Datei zu lesen

Frage Entwicklung Batch & Shell

Mitglied: Privex007

Privex007 (Level 1) - Jetzt verbinden

24.10.2014, aktualisiert 25.10.2014, 1046 Aufrufe, 5 Kommentare

Hallo zusammen,

ich benötige eine Möglichkeit meine Dateien (txt, csv und xls) zu durchforsten und meine Mailadressen in eine separate TXT-Datei abzulegen.
Ich weiß das man das mit einem VBS-Script wunderbar hinbekommt aber ich habe null Ahnung vom Coden.

Perfekt wäre natürlich wenn man einen ganzen Ordner durchsuchen kann.

Vielen Dank für eure Hilfe!

Gruß

Privex007
Mitglied: rubberman
24.10.2014 um 16:01 Uhr
Hallo Privex007, willkommen im Forum.

ich benötige eine Möglichkeit meine Dateien (txt, csv und xls) zu durchforsten und meine Mailadressen in eine separate TXT-Datei abzulegen.
Joa, wir schreiben auch mal ein paar Zeilen fertigen Code. Voraussetzung ist aber, dass du zumindest konkret wirst, wie die Daten vorliegen und wie sie Ausgegeben werden sollen. Außerdem: Benötigst du nur die gefundenen Adressen oder sind diese irgendwie mit Zusatzdaten verlinkt, die du auch brauchst?
Mit 2 hingeschmissenen Sätzen ohne Beschreibung und Beispielen wird das vermutlich nichts.

Grüße
rubberman
Bitte warten ..
Mitglied: Privex007
24.10.2014 um 16:13 Uhr
Da hast du Recht. Ein bisschen mehr hätte ich euch erzählen können.

Also hauptsächlich habe ich "txt"-Dateien die gefüllt sind mit einigem an Text (Briefe etc.). Daraus möchte ich nur die reine Emailadresse filtern "xxxx@xxx.xx". Manchmal habe ich auch "csv"- und "xls"-Dateien wo die Emailadressen in verschiedenen Spalten vorkommen.
Es sind keine Zusatzdaten verlinkt.

Ich habe einen Code-Schnipsel der mir ein bisschen was macht aber nicht vollständig:



Option Explicit

Dim objArgs, fso, strFile, strTestString
Dim strPattern, strAllMatches

Set objArgs = WScript.Arguments

ErrCheck objArgs.Count < 1, 1, "No argument specified."

strFile = objArgs(0)

Set fso = CreateObject("Scripting.FileSystemObject")
ErrCheck Not fso.FileExists(strFile), 1, "File supplied as argument cannot be found: '" & strFile & "'"

'# WScript.Echo "Checking file contents for email addresses: '" & strFile & "'" & vbCrlf

strPattern = "([\w-\.]+)@\w{2,}(\.\w{2,}){1,5}"

strTestString = fso.OpenTextFile(strFile, 1).ReadAll

strAllMatches = fGetMatches(strPattern, strTestString)

If strAllMatches <> "" Then
WScript.Echo strAllMatches
Else
WScript.Echo "-- None Found --"
End If

'# WScript.Echo vbCrlf & "End of " & WScript.ScriptName

Function fGetMatches(sPattern, sStr)
Dim regEx, retVal, sMatch, colMatches, temp
Set regEx = New RegExp ' Create a regular expression.
regEx.Pattern = sPattern ' Set pattern.
regEx.IgnoreCase = True ' Set case insensitivity.
regEx.Global = True ' Set global applicability.

Set colMatches = regEx.Execute(sStr) ' Execute search.

If colMatches.Count = 0 Then
temp = ""
Else
For Each sMatch In colMatches
temp = temp & sMatch & "¶"
Next
temp = Left(temp, Len(temp) - 1)
temp = Replace(temp, "¶", vbCrlf)
End If
fGetMatches = temp
End Function

Sub ErrCheck(blTest, iErrNum, sTxt)
Dim sErrText
If Not blTest Then Exit Sub
sErrText = "Error: " & sTxt
MsgBox sErrText, vbSystemModal + vbCritical, "Error in: " & WScript.ScriptName
WScript.Quit iErrNum
End Sub



Wenn ich meine "txt"-Datei auf die ausführbare "vb"-Datei per Drag and Drop ziehe, dann meldet er mir eine MessageBox mit leider nur einer einzigen Emailadresse. Ich bräuchte die Ausgabe in einer separaten "txt"-Datei und natürlich mit allen enthaltenen Adressen.

Habt ihr da Hilfe für mich?

Vielen Dank schonmal im Voraus!

Gruß

Privex007
Bitte warten ..
Mitglied: 114757
24.10.2014, aktualisiert um 16:52 Uhr
Hallo,
mit Powershell geht dies auch komfortabel und kurz, ohne jetzt mal xls Dateien zu beachten
(diese müsste man via Code öffnen und dann dann auswerten, geht aber auch mit etwas mehr Aufwand ...)
ginge es ungefähr so für alle txt und csv-Dateien in allen Unterordnern eines Ordners:
01.
$allMails = 'd:\all_mails.txt' 
02.
gci "D:\Ordner\*" -Include "*.csv","*.txt" -recurse | %{([regex]'(?i)[a-z0-9._%+-]+@[a-z0-9.-]+\.[a-z]{2,6}').matches((gc $_.Fullname)) | select -Expand Value | out-file $allMails -Append}
Gruß
jodel32
Bitte warten ..
Mitglied: rubberman
LÖSUNG 24.10.2014, aktualisiert 26.10.2014
Hallo Privex007,

lass mal folgendes Script in deinem Verzeichnis laufen:
01.
Option Explicit 
02.
Const strOutFile = "emailaddresses.txt" 
03.
 
04.
Const ForReading = 1, ForWriting = 2 
05.
Dim objFSO, objFolder, objInFile, objOutFile, objStream, objRegex, colMatches, _ 
06.
    objExcelApp, objWorkbook, objWorksheet, objCell, _ 
07.
    strFolderpath, strFilepath, strExtension, strContent, strMatch 
08.
 
09.
Set objFSO = CreateObject("Scripting.FileSystemObject") 
10.
 
11.
Set objRegex = New RegExp 
12.
objRegex.Pattern = "\b[a-z0-9!#$%&'*+/=?^_`{|}~-]+(?:\.[a-z0-9!#$%&'*+/=?^_`{|}~-]+)*@(?:[a-z0-9](?:[a-z0-9-]*[a-z0-9])?\.)+[a-z0-9](?:[a-z0-9-]*[a-z0-9])?\b" 
13.
objRegex.IgnoreCase = True 
14.
objRegex.Global = True 
15.
 
16.
Set objFolder = objFSO.GetFolder(objFSO.GetParentFolderName(WScript.ScriptFullName)) 
17.
 
18.
Set objOutFile = objFSO.OpenTextFile(strOutfile, ForWriting, True) 
19.
 
20.
Set objExcelApp = CreateObject("Excel.Application") 
21.
objExcelApp.Visible = False 
22.
 
23.
 
24.
For Each objInFile In objFolder.Files 
25.
  If Not StrComp(objInFile.Name, strOutfile, vbTextCompare) = 0 Then 
26.
    strFilepath = objInFile.Path 
27.
    strExtension = objFSO.GetExtensionName(strFilepath) 
28.
 
29.
    If StrComp(strExtension, "txt", vbTextCompare) = 0 Or StrComp(strExtension, "csv", vbTextCompare) = 0 Then 
30.
 
31.
      Set objStream = objInFile.OpenAsTextStream(ForReading) 
32.
      strContent = objStream.ReadAll 
33.
      Set colMatches = objRegex.Execute(strContent) 
34.
      If colMatches.Count <> 0 Then 
35.
        For Each strMatch In colMatches 
36.
          objOutFile.WriteLine strMatch 
37.
        Next 
38.
      End If 
39.
      objStream.Close 
40.
 
41.
    ElseIf StrComp(strExtension, "xls", vbTextCompare) = 0 Then 
42.
 
43.
      Set objWorkbook = objExcelApp.Workbooks.Open(strFilepath, 0, True) 
44.
      For Each objWorksheet In objWorkbook.Worksheets 
45.
        For Each objCell In objWorksheet.UsedRange.Cells 
46.
          strContent = CStr(objCell) 
47.
          If strContent <> "" Then 
48.
            Set colMatches = objRegex.Execute(strContent) 
49.
            If colMatches.Count <> 0 Then 
50.
              For Each strMatch In colMatches 
51.
                objOutFile.WriteLine strMatch 
52.
              Next 
53.
            End If 
54.
          End If 
55.
        Next 
56.
      Next 
57.
      objWorkbook.Close False 
58.
 
59.
    End If 
60.
 
61.
  End If 
62.
Next 
63.
 
64.
objExcelApp.Quit 
65.
objOutFile.Close

Grüße
rubberman

EDIT Zeile 45 ".Cells" hinzu (ändert nichts am Verhalten des Codes)
Bitte warten ..
Mitglied: Privex007
25.10.2014 um 17:53 Uhr
Hallo rubberman,

klappt perfekt. You are the best!

Dankeschön!

Gruß

Privex007
Bitte warten ..
Ähnliche Inhalte
Batch & Shell
Per Batch eine XLS-Datei in eine TXT-Datei umwandeln (5)

Frage von skiing69 zum Thema Batch & Shell ...

XML
gelöst CSV bzw. XLS Dateien in ein XML Schema einbinden (3)

Frage von fisi-flo zum Thema XML ...

Java
gelöst Net user per script aus txt oder csv für FTP (15)

Frage von OlliPWS zum Thema Java ...

Batch & Shell
gelöst Werte aus CSV in TXT - Powershell (20)

Frage von Komoran12 zum Thema Batch & Shell ...

Neue Wissensbeiträge
Windows Update

Novemberpatches und Nadeldrucker bereiten Kopfschmerzen

(14)

Tipp von MettGurke zum Thema Windows Update ...

Windows 10

Abhilfe für Abstürze von CDPUsersvc auf Win10 1607 und 2016 1607

(7)

Tipp von DerWoWusste zum Thema Windows 10 ...

RedHat, CentOS, Fedora

Fedora 27 ist verfügbar

Information von Frank zum Thema RedHat, CentOS, Fedora ...

Heiß diskutierte Inhalte
Windows Server
Kennwort vergessen bei Hyper vserver 2012r (12)

Frage von jensgebken zum Thema Windows Server ...

Linux Desktop
Bildschirmauflösung unter Linux festlegen (12)

Frage von itebob zum Thema Linux Desktop ...

Windows Userverwaltung
gelöst Administrator hat alle Rechte verloren (10)

Frage von mrdead zum Thema Windows Userverwaltung ...

LAN, WAN, Wireless
Gebäude mit WLAN ausstatten (9)

Frage von udobec zum Thema LAN, WAN, Wireless ...