Adobe Reader schliesst sich sofort wieder nach der Öffnung

@echo off&setlocal EnableExtensions DisableDelayedExpansion&title acrord32 fix&echo(&set "AcroRdVer="  
for /f "delims=" %%i in ('reg query "HKCU\Software\Adobe\Acrobat Reader"^|findstr /rec:"Acrobat Reader\\[0-9][0-9]*\.[0-9]*"') do set "AcroRdVer=%%~nxi"  
if not defined AcroRdVer (
  color c&echo *** Unable to find the latest version number of Acrobat Reader. ***
  echo(&echo              *** No action applied to fix problems! ***&echo(&echo(&pause&goto :eof
)
echo  Latest Acrobat Reader Version: %AcroRdVer%&echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo(&echo  *** Kill AcroRd32.exe (only if running) ***&taskkill /f /im "acrord32.exe"  
echo(&set "winver="&set "rdmsgproc="  
for /f "tokens=2 delims=" %%i in ('ver') do for /f "tokens=2" %%j in ("%%i") do set "winver=%%j"  
if %winver:~,1%==5 (
  set "rdmsgproc=1"&echo  *** - XP - delete ReaderMessages ***  
  del /f "%APPDATA%\Adobe\Acrobat\%AcroRdVer%\ReaderMessages" 2>&1|findstr .||echo successful  
)
if %winver:~,1% gtr 5 (
  set "rdmsgproc=1"&echo  *** - Vista and newer - delete ReaderMessages ***  
  del /f "%USERPROFILE%\AppData\LocalLow\Adobe\Acrobat\%AcroRdVer%\ReaderMessages" 2>&1|findstr .||echo successful  
)
if not defined rdmsgproc (
  color c&echo *** No action specified to delete ReaderMessages under Windows version %winver%. ***&echo(
)
echo(&echo  *** "HKCU\Software\Adobe\Acrobat Reader\%AcroRdVer%\IPM" bShowMsgAtLaunch ***  
reg add "HKCU\Software\Adobe\Acrobat Reader\%AcroRdVer%\IPM" /v "bShowMsgAtLaunch" /t REG_DWORD /d 0 /f 2>&1|findstr .  
echo(&echo  *** "HKCU\Software\Adobe\Acrobat Reader\%AcroRdVer%\IPM" bDontShowMsgWhenViewingDoc ***  
reg add "HKCU\Software\Adobe\Acrobat Reader\%AcroRdVer%\IPM" /v "bDontShowMsgWhenViewingDoc" /t REG_DWORD /d 1 /f 2>&1|findstr .  
echo(&pause