Problem bei Zeit Variable in Batch unter engl. Win95

echo. | time | find "%key%" | sed s/[:.]/-/g > }{.bat  

... | sed s/[:.]//g

... | sed s/[^^0-9]//g

IF NOT "%OS%"=="Windows_NT" echo "%0 läuft nur unter WinNT oder höher. Sorry." && GOTO :eof  

set xtime=%time:~0,8%
echo %xtime::=-%

@REM ---------snipp GetWin95ENTime.bat Placed in the Public Domain Biber 2007
@echo off
REM ---Time-Format möge sein 08:14:56.03p 
REM ---ab hier anpassen!!!!!!!!!!!!!!
Set $tmp$=c:\temp\timetmp.txt
Set $find$=c:\Win95\find.exe
REM [unter WinNT++] Set $tmp$=%temp%\timetmp.txt
REM [unter WinNT++] SET $find$=find
REM ---bis hier anpassen!!!!!!!!!!!!!
REM Mit welchem Parameter/für welche Phase ist der Batch gerufen...
if "%1"=="" goto Init  
if "%2"=="" goto GetHours  
if "%3"=="" goto GetMinutes  

REM Sekunden extrahieren Time-Format möge sein 08:14:56.03p 
%$find$% ":%3." %$tmp$% > nul  
REM ---ACHTUNG: bei Dt-Datumsformat ist es ein Komma statt des Punkts!!
REM [Dt] %$find$% ":%3," %$tmp$% > nul  

if not errorlevel==1 if errorlevel==0 set SS=%3
goto done

REM Hier die Minuten rausfieseln:Time-Format 08:14:56.03p 
:GetMinutes
%$find$% ":%2:" %$tmp$% >nul  
if not errorlevel==1 if errorlevel==0 set MM=%2
goto done

REM ...Stunden rausdröseln ...die haben ein Leerzeichen vor der Ziffer..
:GetHours
%$find$% " %1:" %$tmp$% >nul  
if not errorlevel==1 if errorlevel==0 set HH=%1
goto done

REM Die Zeit mit dem Befehl "echo.|time" in eine Datei schreiben  
REM Die brauchen wir nämlich so ein- oder zweimal in dem Ablauf
:Init
echo.|time > %$tmp$%

REM Für alle Zeit-Teile [Stunden, Minuten, Sekunden] 
REM die Alternativen durchflöhen... hilft ja nix...
REM Dafür brauchen wir halt diese Dummy-Parameter "x",   
REM um Stunden als Stunden, Minuten als Minuten etc zu erkennen.
FOR %%i IN (0 1 2 3 4 5 6 7 8 9 10 11 12) DO CALL %0 %%i
REM --- Die nächste Zeile entREMen, wenn 24-Stundenformat
REM --- FOR %%i IN (13 14 15 16 17 18 19 20 21 22 23) DO CALL %0 %%i
REM ...alle Minuten-Anzeigen prüfen
FOR %%i IN (00 01 02 03 04 05 06 07 08 09) DO CALL %0 hr %%i
FOR %%i IN (10 11 12 13 14 15 16 17 18 19) DO CALL %0 hr %%i
FOR %%i IN (20 21 22 23 24 25 26 27 28 29) DO CALL %0 hr %%i
FOR %%i IN (30 31 32 33 34 35 36 37 38 39) DO CALL %0 hr %%i
FOR %%i IN (40 41 42 43 44 45 46 47 48 49) DO CALL %0 hr %%i
FOR %%i IN (50 51 52 53 54 55 56 57 58 59) DO CALL %0 hr %%i
REM ...alle Sekunden-Anzeigen prüfen 
REM ---hier erweiterbar auch auf zwei Blöcke mit (00p 01p ...)
REM --- bzw 00a 01a ...59a) an Ende, um am/pm zu unterscheiden
FOR %%i IN (00 01 02 03 04 05 06 07 08 09) DO CALL %0 hr mm %%i
FOR %%i IN (10 11 12 13 14 15 16 17 18 19) DO CALL %0 hr mm %%i
FOR %%i IN (20 21 22 23 24 25 26 27 28 29) DO CALL %0 hr mm %%i
FOR %%i IN (30 31 32 33 34 35 36 37 38 39) DO CALL %0 hr mm %%i
FOR %%i IN (40 41 42 43 44 45 46 47 48 49) DO CALL %0 hr mm %%i
FOR %%i IN (50 51 52 53 54 55 56 57 58 59) DO CALL %0 hr mm %%i

REM Aufräumen, Tempdatei löschen
del %$tmp$%
:done

>getWin95ENtime.bat
.....(etwas später...)
>echo %HH%--%MM%--%SS%
20--57--01

Set $find$=:\Win95\find.exe

REM [unter WinNT++] SET $find=find