Textdatei bearbeiten, vergleichen, auslesen und in eine vorhandene Textdatei einfügen.

@echo off & setlocal
set "Quelle=D:\quelle.txt"  
set "QuellTemp=%temp%\Quelle.txt"  

set /p Ziel=<"%Quelle%"  
for /f "delims=:" %%i in ('findstr /n "^" "%Quelle%"') do set "ZNr=%%i"  
move "%Quelle%" "%QuellTemp%"  
for /f "tokens=1-2* delims=:;" %%i in ('findstr /n "^" "%QuellTemp%"') do if %%i neq %ZNr% (echo\%%j)>>"%Quelle%"  
echo Zieldatei: %Ziel%

set "Ziel=%Ziel%.txt"  
set ZNr=
for /f "delims=:" %%i in ('findstr /n "^" "%Ziel%"') do set "ZNr=%%i"  
if not defined ZNr echo Keine Daten in "%Ziel%" gefunden! & pause & goto :eof  
set /a Ab=%ZNr%-5
if %Ab% lss 0 set Ab=0
for /f %%i in ('more +%Ab% "%Ziel%"') do echo %%i  

1.3694
1.3695<<<<<<1
1.3680<<<<<<2
1.3686<<<<<<3
1.3635<<<<<<4
1.3642<<<<<<5
< ab hier neue Daten aus Quelldatei anfügen

...
1.3695 ;<<<<<<1 in Zieldatei schon vorhanden
1.3680 ;<<<<<<2 in Zieldatei schon vorhanden
1.3686 ;<<<<<<3 in Zieldatei schon vorhanden
1.3635 ;<<<<<<4 in Zieldatei schon vorhanden
1.3642 ;<<<<<<5 in Zieldatei schon vorhanden 
1.3652 ;<<<<<<  ab hier neue Daten in Zieldatei anfügen
...

@echo off & setlocal
set "Quelle=quelle.txt"  
set "QuellTemp=%temp%\Quelle.txt"  

::Zieldateinamen ermitteln
set /p Ziel=<"%Quelle%"  

::Zeilenanzahl der Quelldatei feststellen und in %ZNr% speichern
for /f "delims=:" %%i in ('findstr /n "^" "%Quelle%"') do set "ZNr=%%i"  

::Quelldatei in Temporärdatei umwandeln und aus dieser ...
move "%Quelle%" "%QuellTemp%"  

::... zeilenweise neu erstellen (und dabei das Semikolon durch
::  Deklaration als Trennzeichen eliminieren) - 
::  dazu alle Zeilen mit Ausnahme der letzten Zeile (zu erkennen
::  durch den Vergleich der Zeilennummer in %%i mit %ZNr%)
::  in die neue Quelldatei schreiben
for /f "tokens=1-2* delims=:;" %%i in ('findstr /n "^" "%QuellTemp%"') do if %%i neq %ZNr% (echo\%%j)>>"%Quelle%"  

::Zieldateinamen um Dateityp ergaenzen 
set "Ziel=%Ziel%.txt"  

::Zeilenanzahl der Zieldatei feststellen und in %ZNr% speichern
set ZNr=
for /f "delims=:" %%i in ('findstr /n "^" "%Ziel%"') do set "ZNr=%%i"  

::falls ZNr keinen Wert hat, wurden keine Zeilen gefunden - Abbruch
if not defined ZNr echo Keine Daten in "%Ziel%" gefunden! & pause & goto :eof  

::Position der Zeile, nach welcher die letzten 5 Zeilen der Zieldatei beginnen
set /a Ab=%ZNr%-5

::sollte die Zieldatei weniger als 5 Zeilen enthalten, nur die
::  tatsächlich vorhandenen Zeilen verwenden
if %Ab% lss 0 set Ab=0

::Variablen initialisieren
set /a ZAnz=0 & set "Vergleich=" & set "Erste="  

::Zeilen ab der berechneten Position in der Zieldatei zeilenweise auslesen
::  und im Unterprogramm :ProcessLine (beim Aufruf Übergabe der Zeile)
::  zu einem Vergleichs-String zusammensetzen
for /f %%i in ('more +%Ab% "%Ziel%"') do call :ProcessLine "%%i"  

::Variablen initialisieren
set "ZNr=" & set "Fertig="  

::alle Vorkommen der ersten Zeile des aus der Zieldatei entnommenen
::  Zeilenblocks von (bis zu) 5 Zeilen suchen und jeweils unter
::  Übergabe der Zeilennummer das Uterprogramm :ProcessBlock
::  zur Überprüfung, ob der gesuchte Block gefunden wurd, aufrufen,
::  falls dieser nicht berits vorher gefunden wurde (dann ist die
::  Variable %Fertig% schon gesetzt)
for /f "delims=:" %%i in ('findstr /n "%Erste%" "%Quelle%"') do if not defined Fertig call :ProcessBlock %%i  

::Ende Hauptprogramm
goto :eof

:ProcessLine
::erste Zeile des Blocks aus der Zieldatei in Variable schreiben
if not defined Erste set "Erste=%~1"  

::Zeilenanzahl hochzählen
set /a ZAnz+=1

::Vergleichs-String um übergebenen Zeileninhalt ergänzen
set "Vergleich=%Vergleich%%~1"  
goto :eof

:ProcessBlock
::%Noch% mit der Anzahl der Zeilen des Blocks vorbelegen
::%Ab% auf die Nummer der letzten zu überspringenden Zeile
::  (=1 Zeile vor Beginn des zu prüfenden Blocks in der
::   Quelldatei) setzen
set /a Noch=%ZAnz% & set "Vergleich2=" & set /a Ab=%1-1  

::Zeilen ab Beginn des Blocks durchgehen und daraus zweiten
::Vergleichs-String erstellen
for /f %%a in ('more +%Ab% "%Quelle%"') do call :ProcessLine2 "%%a"  

::Vergleich der beiden Strings - bei Übereinstimmung wurde
::der Block in der Quelldatei gefunden und kann an die
::Zieldatei angefügt werden; durch Setzen der Variablen
::%Fertig% signalisieren, dass nicht mehr weitergesucht
::werden muss
if "%Vergleich%"=="%Vergleich2%" (  
    more +%Ab% "%Quelle%">>"%Ziel%"  
    set "Fertig=True"  
)
goto :eof

:ProcessLine2
::Soferne noch nicht gleich viele Zeilen, wie im Block
::  aus der Zieldatei enthalten sind, in den zweiten
::  Vergleichs-String aufgenommen wurden, die über-
::  gebene Zeile hinufügen
if %Noch% gtr 0 set "Vergleich2=%Vergleich2%%~1"  

::Restanzahl der hinzuzufügenden Zeilen verringern
set /a Noch-=1
goto :eof

@Echo off & SetLocal EnableDelayedExpansion
CD /D "D:\Neuer Ordner"  
Set Src=Quelle.txt
set /P Dst=<"%Src%"  
set "Dst=%Dst%.txt"  
if Not Exist "%Dst%" Echo kann Ziel %Dst% nicht finden & Exit /B 1  

:: Ermittle Länge von Dst
set DstCnt=0
For /f %%A in (
  'Findstr "^[0-9][0-9.]" "%Dst%" ^|find /V /C "#"'  
    ) Do Set /A "DstCnt=%%A"  

If %DstCnt% LSS 5 Echo Weniger als 5 Werte in %Dst% & Exit /B 2
Set /A DstCnt-=5

:: Letzte 5 einlesen
Set OLCnt=0
For /f "skip=%DstCnt% Delims=;" %%A in (  
  'Findstr "^[0-9][0-9.]" "%Dst%"'  
    ) Do Set "Overlap!OLCnt!=%%A" & Set /A "OLCnt+=1"  

:: Quelle einlesen
Set OLCnt=0
If defined Last Set "Last="  

For /f "Delims=; " %%A in ('More +3 %Src%') Do Call :Check %%A  

If %OLCnt% LSS 5 Echo Konnte keine Ueberlappung ermitteln & Exit /B 3
Echo Done
Exit /B 0

:Check
if %OLCnt% Gtr 4 Goto :Append
If "!OverLap%OLCnt%!" EQU "%1" Set /A "OLCnt+=1" & Goto :Eof  
IF %OLCnt% GTR 0 Set "OLCnt=0" & goto :Check  
Set OLCnt=0
Goto :Eof

:Append
Echo Append %Last%
If Defined Last >> "%Dst%" Echo.%Last%  
Set "Last=%1"  
Goto :Eof

@Echo off
PushD "D:\Neuer Ordner"  
Set AnzNeue=5
Set AnzAlte=10
Set Out="Quelle.txt"  
Set In="EURUSD - 4 Stunden.txt"  

:: Schreibe Header
 >%Out% Echo EURUSD - 4 Stunden
>>%Out% ECHO.
>>%Out% ECHO.High

:: Ermittle Zeilenzahl
For /f %%A in ('find /V /C "" ^<%In%') Do Set InCnt=%%A  
Set /A Skip=%InCnt% - %AnzAlte%

:: Übernehme vorhandene
For /F %%A in ('More +%SKip% %In%') Do (Echo.%%A;)>>%Out%  

Echo Anhängen
For /L %%A in (1,1,%AnzNeue%) Do Call :AppRand
PopD
Goto :Eof

:AppRand
Set /A Kurs="%Random% %% 9999"  
Set Kurs=0000%Kurs%
Echo.1.%Kurs:~-4%;
1>>%Out% Echo.1.%Kurs:~-4%;
Goto :Eof

for /f "delims=:" %%i in ('findstr /n /x "%Erste%" "%Quelle%"') do if not defined Fertig call :ProcessBlock %%i

set /a Ab+=5