52634
52634
Sep 22, 2007, updated at Sep 24, 2007 (UTC)
view5399
view10
0
Goto Top

Wieso funktioniert das goto nicht?

GermansolvedQuestionBatch, ShellDevelopment

Hallo...

Ich habe eine batch in der überprüft wird ob ein Rechner existiert, die Abfrage funktioniert aber das springen zur benötigten Funktion wird ignoriert und alles abgearbeitet... Hoffe ihr könntt mir helfen^^.

Hier die Batch:
@echo OFF
echo Ueberpruefen ob Netzrechner vorhanden sind!
ping 192.168.2.33 -n 1 >> "%tmp%\nlw1.txt"  
ping 192.168.2.30 -n 1 >> "%tmp%\nlw2.txt"  
ping 192.168.2.34 -n 1 >> "%tmp%\nlw3.txt"  
goto :nlw1suchen: 

:nlw1suchen:
find /I "Antwort von 192.168.2.33" "%tmp%\nlw1.txt"  
IF   %ERRORLEVEL% == 1 goto :nlw1:
IF   %ERRORLEVEL% == 0 goto :nlw2suchen:

:nlw1:
echo Netzlaufwerke-Server werden hinzugefuegt.
net use z: \\192.168.2.33\A /user:geheim_;-) geheim_;-) /PERSISTENT:NO 
net use y: \\192.168.2.33\E /user:geheim_;-) geheim_;-) /PERSISTENT:NO 
net use x: \\192.168.2.33\C$ /user:geheim_;-) geheim_;-) /PERSISTENT:NO
del "%tmp%nlw1.txt"  
goto :nlw2suchen:

:nlw2suchen:
find /I "Antwort von 192.168.2.30" "%tmp%\nlw2.txt"  
IF   %ERRORLEVEL% == 1 goto :nlw2:
IF   %ERRORLEVEL% == 0 goto :nlw3suchen:

:nlw2:
echo Netzlaufwerke-Dad werden hinzugefuegt.
net use i: \\192.168.2.30\C$ /user:geheim_;-) geheim_;-) /PERSISTENT:NO
net use m: \\192.168.2.30\D$ /user:geheim_;-) geheim_;-) /PERSISTENT:NO
del "%tmp%\nlw2.txt"  
goto :nlw3suchen:

:nlw3suchen:
find /I "Antwort von 192.168.2.34" "%tmp%\nlw3.txt"  
IF   %ERRORLEVEL% == 1 goto :nlw3:
IF   %ERRORLEVEL% == 0 goto :nwdsuchen:

:nlw3:
echo Netzlaufwerke-Desktop werden hinzugefuegt.
net use n: \\192.168.2.34\C$ /user:geheim_;-) geheim_;-) /PERSISTENT:NO
net use o: \\192.168.2.34\A$ /user:geheim_;-) geheim_;-) /PERSISTENT:NO
net use p: \\192.168.2.34\F$ /user:geheim_;-) geheim_;-) /PERSISTENT:NO
del "%tmp%\nlw3.txt"  
goto :nwdsuchen:

:nwdsuchen:
echo Netzwerkdrucker werden hinzugefuegt.
reg query "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Devices" >> "%tmp%\nwd.txt"  
find /I "\\192.168.2.33\HP-Drucker" "%tmp%\nwd.txt"  
IF   %ERRORLEVEL% == 1 rundll32 printui.dll,PrintUIEntry /in /n "\\192.168.2.33\HP-Drucker" goto :nwd:  

:nwd:
rundll32 printui.dll,PrintUIEntry /y /n "\\192.168.2.33\HP-Drucker"  
del "%tmp%\nwd.txt"  

echo MySQL wird gestoppt!
net stop mysql

PAUSE

[Edit Biber 24.9.] Skript als formatiert. [/Edit]
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 69283

Url: https://administrator.de/contentid/69283

Printed on: April 26, 2024 at 05:04 o'clock

10 Comments
Latest comment
Goto Top
Member: EvilMoe
EvilMoe Sep 22, 2007 at 22:00:12 (UTC)
Goto Top
Muss am ende ein doppelpunkt stehen? Ich bin zwar nicht der freak bei batches, aber ich meine mal das ich am ende nie ein doppelpunkt verwendet habe...
Member: Dynadrate
Dynadrate Sep 22, 2007 at 22:07:57 (UTC)
Goto Top
Ohne die Sache ausprobiert zu haben: EvilMoe hat recht!
Member: TuXHunt3R
TuXHunt3R Sep 22, 2007 at 22:45:19 (UTC)
Goto Top
Guter Platz um eine Frage zu deponieren:

Sind Ziffern und oder Sonderzeichen in Sprungmarken erlaubt? Ich habe bisher aus Sicherheit keine verwendet....
Member: screen2
screen2 Sep 23, 2007 at 07:02:53 (UTC)
Goto Top
Bei goto müssen beide Doppelpunkte weg und bei der Sprungmarke dürfen sie nur am Anfang stehen.
Doch noch eine Frage von mir sry hoffe es passt jetzt hier, was bewirkt die Option Persistent: NO bei der Funktion net use in deinem Script und was heißt %ERRORLEVEL% ==0.

screen2
Mitglied: 52634
52634 Sep 23, 2007 at 10:34:47 (UTC)
Goto Top
Das /Persistent:NO bedeutet das die Netzlaufwerke nur bis zur Abmeldung bestehen und dann jedesmal bei der Anmeldung neu verbunden werden. Das mit dem Errorlevel == 0, wenn in "find" was nichts findet gibt es eine 0 aus, hoffe hab das gut erklärt , den teil hab ich nämlich mit Hilfe eines Lehrers gemacht. Ich hab das jetzt so abgeänder mit den Sprungmarken und dem goto aber die Batch führt sie immer noch aus..? hmmm
Member: bastla
bastla Sep 23, 2007 at 12:16:52 (UTC)
Goto Top
@screen2

Bei goto müssen beide Doppelpunkte weg und bei der Sprungmarke dürfen sie nur am Anfang stehen.
kann man so nicht stehen lassen - ich würde das eher so formulieren:

Bei goto können beide Doppelpunkte weg (oder jeder einzelne der beiden) und bei der Sprungmarke muss einer am Anfang stehen (am Ende können so viele, wie in eine Batchzeile eben reinpassen, inkl etwa einem Kommentar, folgen).

Beispiel:
@echo off
goto :($)1Label@§Test-0816:
echo Kein Sprung!
pause
goto :eof

:($)1Label@§Test-0816{{comment_single_line_remark:0}}
echo Angekommen ...
pause
Die Zeile "echo Kein Sprung"! ist nur zu Demo-Zwecken gedacht, da sie ohnehin nie errreicht wird (bei nicht gefundenem Sprungziel verursacht bereits die "goto"-Zeile einen Fehler).
@TuXHunt3R
Hinsichtlich der Sonderzeichen ist sicherlich etwas Vorsicht geboten, da ja im Batch zB "!%&/?+ jeweils eine eigene Bedeutung haben (können), aber, wie das Beispiel oben zeigen soll: grundsätzlich verboten sind Sonderzeichen hier nicht.

Grüße
bastla
Mitglied: 52634
52634 Sep 23, 2007 at 12:24:19 (UTC)
Goto Top
Was heist in dem Bsp: goto :eof?
Member: bastla
bastla Sep 23, 2007 at 12:27:18 (UTC)
Goto Top
Hallo MGrote!

Das Problem rührt daher, dass "find" einen Errorlevel 1 dann liefert, wenn der gesuchte Text nicht gefunden wurde, daher also
find /I "Antwort von 192.168.2.33" "%tmp%\nlw1.txt">nul  
if errorlevel 1 goto :nlw2suchen:
echo Netzlaufwerke-Server werden hinzugefuegt.
Kürzer:
find /I "Antwort von 192.168.2.33" "%tmp%\nlw1.txt">nul||goto :nlw2suchen:  
echo Netzlaufwerke-Server werden hinzugefuegt.
Noch kürzer (soferne der Batch unter XP läuft - W2000 hat mit dem "ping"-Errorlevel Probleme):
ping 192.168.2.33 -n 1 >nul||goto :nlw2suchen:
echo Netzlaufwerke-Server werden hinzugefuegt.

ping 192.168.2.33 -n 1 >nul&&(
    echo Netzlaufwerke-Server werden hinzugefuegt.
    net use z: \\192.168.2.33\A /user:geheim  geheim  /PERSISTENT:NO
)
"goto :eof" bedeutet: "Batch beenden" oder, bei Verwendung in einem ge"call"ten Block: "Unterprogramm beenden - Rücksprung"

Grüße
bastla

[Edit] ">nul" zu den "ping"-Zeilen hinzugefügt - soll, so wie bei den "find"-Zeilen - die Optik etwas verbessern. [/Edit]
Mitglied: 52634
52634 Sep 23, 2007 at 12:49:29 (UTC)
Goto Top
Daaaaaaaaaaaaanke... face-smile
jetzt funktioniert das so wie es soll^^.
Member: Biber
Biber Sep 24, 2007 at 05:25:41 (UTC)
Goto Top
Moin MGrote,

auch wenn der Beitrag schon als gelöst markiert ist, möchte ich noch anmerken:

@echo OFF
echo Ueberpruefen ob Netzrechner vorhanden sind!
ping 192.168.2.33 -n 1 >> "%tmp%\nlw1.txt"  
ping 192.168.2.30 -n 1 >> "%tmp%\nlw2.txt"  
ping 192.168.2.34 -n 1 >> "%tmp%\nlw3.txt"  
::###########----> Na toll, hier wird immer an evtl. bestehende nlwX.txt angefügt.
::###########---> Schau doch mal weiter unten, ob in JEDEM Fall auch die nlwX'e gelöscht werden....;-) 
goto :nlw1suchen: 

:nlw1suchen:
find /I "Antwort von 192.168.2.33" "%tmp%\nlw1.txt"  
IF   %ERRORLEVEL% == 1 goto :nlw1:
<b>IF   %ERRORLEVEL% == 0 goto :nlw2suchen:</b>
::########### unabhängig von der Logik (s. bastlas Hinweis): 
::########### das "IF   %ERRORLEVEL% == 0 " ist ohne Sinnverlust entfernbar. Das "goto ..." reicht. 

:nlw1:
echo Netzlaufwerke-Server werden hinzugefuegt.
net use z: \\192.168.2.33\A /user:geheim_;-) geheim_;-) /PERSISTENT:NO 
::######### a) Wenn doch gefühlte 27x auf "\\192.168.2.33" gemapt wird, dann sollte es in eine %variable% 
::######### b) wenn doch gefühlte 27x das (ohnehin defaultwertige) "net use .../Persistent:No" dahintersteht, 
::#########      dann wäre EINE Zeile "Net use /p:no" VOR dem Actionteil pflegeleichter. 
net use y: \\192.168.2.33\E /user:geheim_;-) geheim_;-) /PERSISTENT:NO 
net use x: \\192.168.2.33\C$ /user:geheim_;-) geheim_;-) /PERSISTENT:NO
del "%tmp%nlw1.txt"  
goto :nlw2suchen:

:nlw2suchen:
....
:nlw2:
....

:nlw3suchen:
...

:nlw3:
....
:nwdsuchen:
echo Netzwerkdrucker werden hinzugefuegt.
reg query "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Devices" >> "%tmp%\nwd.txt"  
find /I "\\192.168.2.33\HP-Drucker" "%tmp%\nwd.txt"  
IF   %ERRORLEVEL% == 1 rundll32 printui.dll,PrintUIEntry /in /n "\\192.168.2.33\HP-Drucker" goto :nwd:  
::########## Um noch mal auf die Kernfrage zurückzukommen: Auch dieses GOTO kann nicht funktionieren:
::########## denn nach "RunDLL23 printUI.DLL ..... HP-Drucker" fehlt mindestens ein, beseer zwei "&" 
::########## IF   %ERRORLEVEL% == 1 rundll32 printui.dll,PrintUIEntry .......\HP-Drucker" && goto :nwd: 
::########## Andererseits.... er müsste ja nicht weit goto'en..... er merkt zwar einen Parameterfehler.... 
::########## "'Goto :nwd:' kann ich nich' interpretieren", aber geht natürlich in die Folgezeile.  

:nwd:
rundll32 printui.dll,PrintUIEntry /y /n "\\192.168.2.33\HP-Drucker"  
del "%tmp%\nwd.txt"  

echo MySQL wird gestoppt!
net stop mysql

PAUSE
[Das soll jetzt kein korrigierter, getesteter Batch sein, sondern nur die Ur-Version mit formalen Anmerkungen.]

Grüße
Biber
GermansolvedQuestionBatch, ShellDevelopment
Hotly discussed
gleixnerdCheck of ZFW Firewallgleixnerd - 5 Comments